From 23023dffe24e9acd7db1845cc56c138cdf444ae7 Mon Sep 17 00:00:00 2001
From: Bernardo Meurer <bernardo@meurer.org>
Date: Wed, 9 Jun 2021 23:40:27 -0700
Subject: [PATCH] hqplayerd: init at 4.24.0-61

---
 pkgs/servers/hqplayerd/default.nix | 89 ++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix    |  2 +
 2 files changed, 91 insertions(+)
 create mode 100644 pkgs/servers/hqplayerd/default.nix

diff --git a/pkgs/servers/hqplayerd/default.nix b/pkgs/servers/hqplayerd/default.nix
new file mode 100644
index 000000000000..10524c71612b
--- /dev/null
+++ b/pkgs/servers/hqplayerd/default.nix
@@ -0,0 +1,89 @@
+{ stdenv
+, alsa-lib
+, autoPatchelfHook
+, cairo
+, fetchurl
+, flac
+, gnome
+, gssdp
+, gupnp
+, lib
+, libgmpris
+, llvmPackages_10
+, rpmextract
+, wavpack
+}:
+
+stdenv.mkDerivation rec {
+  pname = "hqplayerd";
+  version = "4.24.0-61";
+
+  src = fetchurl {
+    url = "https://www.signalyst.eu/bins/${pname}/fc33/${pname}-${version}.fc33.x86_64.rpm";
+    sha256 = "sha256-VouqkWRu9lcbCQNmXJayrsZZnhvM5xEZlUyBEkURBOQ=";
+  };
+
+  unpackPhase = ''
+    ${rpmextract}/bin/rpmextract $src
+  '';
+
+  nativeBuildInputs = [ autoPatchelfHook rpmextract ];
+
+  buildInputs = [
+    alsa-lib
+    cairo
+    flac
+    gnome.rygel
+    gssdp
+    gupnp
+    libgmpris
+    llvmPackages_10.openmp
+    wavpack
+  ];
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    # main executable
+    mkdir -p $out/bin
+    cp ./usr/bin/hqplayerd $out/bin
+
+    # udev rules
+    mkdir -p $out/etc/udev/rules.d
+    cp ./etc/udev/rules.d/50-taudio2.rules $out/etc/udev/rules.d
+
+    # kernel module cfgs
+    mkdir -p $out/etc/modules-load.d
+    cp ./etc/modules-load.d/taudio2.conf $out/etc/modules-load.d
+
+    # systemd service file
+    mkdir -p $out/lib/systemd/system
+    cp ./usr/lib/systemd/system/hqplayerd.service $out/lib/systemd/system
+
+    # documentation
+    mkdir -p $out/share/doc/${pname}
+    cp ./usr/share/doc/${pname}/* $out/share/doc/${pname}
+
+    # misc service support files
+    mkdir -p $out/var/lib/${pname}
+    cp -r ./var/hqplayer/web $out/var/lib/${pname}
+  '';
+
+  postInstall = ''
+    substituteInPlace $out/lib/systemd/system/hqplayerd.service \
+      --replace /usr/bin/hqplayerd $out/bin/hqplayerd
+  '';
+
+  postFixup = ''
+    patchelf --replace-needed libomp.so.5 libomp.so $out/bin/hqplayerd
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.signalyst.com/custom.html";
+    description = "High-end upsampling multichannel software embedded HD-audio player";
+    changelog = "https://www.signalyst.eu/bins/${pname}/fc33/${pname}-${version}.fc33.x86_64.changes";
+    license = licenses.unfree;
+    maintainers = with maintainers; [ lovesegfault ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index e00c761321a8..13fcfc6711a9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -19249,6 +19249,8 @@ in
 
   home-assistant-cli = callPackage ../servers/home-assistant/cli.nix { };
 
+  hqplayerd = callPackage ../servers/hqplayerd { };
+
   https-dns-proxy = callPackage ../servers/dns/https-dns-proxy { };
 
   hydron = callPackage ../servers/hydron { };