python3Packages.django-auditlog: init at 2.2.2

pkgs/development/python-modules/django-auditlog/default.nix

@@ -0,0 +1,67 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, setuptools
+, setuptools-scm
+, django
+, python-dateutil
+, freezegun
+, psycopg2
+, postgresql
+, postgresqlTestHook
+, python
+}:
+
+buildPythonPackage rec {
+  pname = "django-auditlog";
+  version = "2.2.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "jazzband";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-QHSGqtpkOgltAg+RlG/Ik3DfEjtSWt45sqlD+Zw4Bh0=";
+  };
+
+  env.SETUPTOOLS_SCM_PRETEND_VERSION = version;
+
+  nativeBuildInputs = [
+    setuptools
+    setuptools-scm
+  ];
+
+  propagatedBuildInputs = [
+    django
+    python-dateutil
+  ];
+
+  nativeCheckInputs = [
+    freezegun
+    psycopg2
+    postgresql
+    postgresqlTestHook
+  ];
+
+  postgresqlTestUserOptions = "LOGIN SUPERUSER";
+
+  checkPhase = ''
+    runHook preCheck
+
+    TEST_DB_USER=$PGUSER \
+    TEST_DB_HOST=$PGHOST \
+    ${python.interpreter} runtests.py
+
+    runHook postCheck
+  '';
+
+  pythonImportsCheck = [ "auditlog" ];
+
+  meta = with lib; {
+    changelog = "https://github.com/jazzband/django-auditlog/blob/v${version}/CHANGELOG.md";
+    description = "A Django app that keeps a log of changes made to an object";
+    downloadPage = "https://github.com/jazzband/django-auditlog";
+    license = licenses.mit;
+    maintainers = with maintainers; [ leona ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -2922,6 +2922,8 @@ self: super: with self; {
 
   django-appconf = callPackage ../development/python-modules/django-appconf { };
 
+  django-auditlog = callPackage ../development/python-modules/django-auditlog { };
+
   django-auth-ldap = callPackage ../development/python-modules/django-auth-ldap { };
 
   django-autocomplete-light = callPackage ../development/python-modules/django-autocomplete-light { };