Merge pull request #222537 from sevenautumns/libgourou

libgourou: init at 0.8.1

maintainers/maintainer-list.nix

@@ -1469,6 +1469,15 @@
     githubId = 12958979;
     name = "Mika Naylor";
   };
+  autumnal = {
+    name = "Sven Friedrich";
+    email = "sven@autumnal.de";
+    github = "sevenautumns";
+    githubId = 20627275;
+    keys = [{
+      fingerprint = "6A2E 7FDD 1037 11A8 B996  E28E B051 064E 2FCA B71B";
+    }];
+  };
   avakhrenev = {
     email = "avakhrenev@gmail.com";
     github = "avakhrenev";

pkgs/development/libraries/libgourou/default.nix

@@ -0,0 +1,48 @@
+{ lib, stdenv, fetchzip, pugixml, updfparser, curl, openssl, libzip
+, installShellFiles }:
+
+stdenv.mkDerivation rec {
+  name = "libgourou";
+  version = "0.8.1";
+
+  src = fetchzip {
+    url = "https://indefero.soutade.fr/p/${name}/source/download/v${version}/";
+    sha256 = "sha256-X56K4z1+k62Q9pxnN8kx35oc7+uJJN/o/tpnKx1FjwE=";
+    extension = "zip";
+  };
+
+  postPatch = ''
+    patchShebangs scripts/setup.sh
+  '';
+
+  postConfigure = ''
+    mkdir lib
+    ln -s ${updfparser}/lib lib/updfparser
+  '';
+
+  nativeBuildInputs = [ installShellFiles ];
+  buildInputs = [ pugixml updfparser curl openssl libzip ];
+
+  makeFlags = [ "BUILD_STATIC=1" "BUILD_SHARED=1" ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dt $out/include include/libgourou*.h
+    install -Dt $out/lib libgourou.so
+    install -Dt $out/lib libgourou.so.${version}
+    install -Dt $out/lib libgourou.a
+    install -Dt $out/bin utils/acsmdownloader
+    install -Dt $out/bin utils/adept_{activate,loan_mgt,remove}
+    installManPage utils/man/*.1
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Implementation of Adobe's ADEPT protocol for ePub/PDF DRM";
+    homepage = "https://indefero.soutade.fr/p/libgourou";
+    license = licenses.lgpl3Plus;
+    maintainers = with maintainers; [ autumnal ];
+    platforms = platforms.all;
+    broken = stdenv.isDarwin;
+  };
+}

pkgs/development/libraries/updfparser/default.nix

@@ -0,0 +1,31 @@
+{ lib, stdenv, fetchzip }:
+
+stdenv.mkDerivation rec {
+  name = "updfparser";
+  version = "unstable-2023-01-10";
+  rev = "a421098092ba600fb1686a7df8fc58cd67429f59";
+
+  src = fetchzip {
+    url = "https://indefero.soutade.fr/p/updfparser/source/download/${rev}/";
+    sha256 = "sha256-Kt1QDj7E0GaT615kJW2MQKF9BeU5U7/95TQKODpxgNI=";
+    extension = "zip";
+  };
+
+  makeFlags = [ "BUILD_STATIC=1" "BUILD_SHARED=1" ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dt $out/include include/*.h
+    install -Dt $out/lib libupdfparser.so
+    install -Dt $out/lib libupdfparser.a
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "A very simple PDF parser";
+    homepage = "https://indefero.soutade.fr/p/updfparser";
+    license = licenses.lgpl3Plus;
+    maintainers = with maintainers; [ autumnal ];
+    platforms = platforms.all;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -21353,6 +21353,8 @@ with pkgs;
 
   libgnurl = callPackage ../development/libraries/libgnurl { };
 
+  libgourou = callPackage ../development/libraries/libgourou { };
+
   libgringotts = callPackage ../development/libraries/libgringotts { };
 
   libgrss = callPackage ../development/libraries/libgrss {
@@ -23908,6 +23910,8 @@ with pkgs;
 
   unicon-lang = callPackage ../development/interpreters/unicon-lang { };
 
+  updfparser = callPackage ../development/libraries/updfparser { };
+
   tsocks = callPackage ../development/libraries/tsocks { };
 
   unixODBC = callPackage ../development/libraries/unixODBC { };