From 4b1975accafc4b65b312d4f53d1be8ed9bc6807b Mon Sep 17 00:00:00 2001
From: colin <colin@uninsane.org>
Date: Sun, 10 Jul 2022 02:06:03 -0700
Subject: [PATCH] zecwallet-lite: init at 1.7.13

closes #166005
---
 .../blockchains/zecwallet-lite/default.nix    | 30 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 ++
 2 files changed, 32 insertions(+)
 create mode 100644 pkgs/applications/blockchains/zecwallet-lite/default.nix

diff --git a/pkgs/applications/blockchains/zecwallet-lite/default.nix b/pkgs/applications/blockchains/zecwallet-lite/default.nix
new file mode 100644
index 000000000000..2a15d2fa9233
--- /dev/null
+++ b/pkgs/applications/blockchains/zecwallet-lite/default.nix
@@ -0,0 +1,30 @@
+{ lib, fetchurl, appimageTools }:
+
+appimageTools.wrapType2 rec {
+  pname = "zecwallet-lite";
+  version = "1.7.13";
+
+  src = fetchurl {
+    url = "https://github.com/adityapk00/zecwallet-lite/releases/download/v${version}/Zecwallet.Lite-${version}.AppImage";
+    hash = "sha256-uBiLGHBgm0vurfvOJjJ+RqVoGnVccEHTFO2T7LDqUzU=";
+  };
+
+  extraInstallCommands =
+    let contents = appimageTools.extract { inherit pname version src; };
+    in ''
+      mv $out/bin/${pname}-${version} $out/bin/${pname}
+
+      install -m 444 -D ${contents}/${pname}.desktop -t $out/share/applications
+      substituteInPlace $out/share/applications/${pname}.desktop \
+        --replace 'Exec=AppRun' 'Exec=${pname}'
+      cp -r ${contents}/usr/share/icons $out/share
+    '';
+
+  meta = with lib; {
+    description = "A fully featured shielded wallet for Zcash";
+    homepage = "https://www.zecwallet.co/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ colinsane ];
+    platforms = [ "x86_64-linux" ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 1c384a14b817..a7955f271172 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -31776,6 +31776,8 @@ with pkgs;
 
   zcash = callPackage ../applications/blockchains/zcash { };
 
+  zecwallet-lite = callPackage ../applications/blockchains/zecwallet-lite { };
+
   lightwalletd = callPackage ../applications/blockchains/lightwalletd { };
 
   openethereum = callPackage ../applications/blockchains/openethereum { };