python3Packages.pysequoia: init at 0.1.14

Also, make `python3Packages.sequoia` throw a message regarding it's
replacement of `python3Packages.sequoia`. The main sequoia-pgp/sequoia
repository doesn't ship Python code since 0.25.0, just a binary.

nixos/doc/manual/release-notes/rl-2311.section.md

@@ -20,6 +20,8 @@
 
 ## Backward Incompatibilities {#sec-release-23.11-incompatibilities}
 
+- `python3.pkgs.sequoia` was removed in favor of `python3.pkgs.pysequoia`. The latter package is based on upstream's dedicated repository for sequoia's Python bindings, where the Python bindings from [gitlab:sequoia-pgp/sequoia](https://gitlab.com/sequoia-pgp/sequoia) were removed long ago.
+
 - `writeTextFile` now requires `executable` to be boolean, values like `null` or `""` will now fail to evaluate.
 
 - The latest version of `clonehero` now stores custom content in `~/.clonehero`. See the [migration instructions](https://clonehero.net/2022/11/29/v23-to-v1-migration-instructions.html). Typically, these content files would exist along side the binary, but the previous build used a wrapper script that would store them in `~/.config/unity3d/srylain Inc_/Clone Hero`.

pkgs/development/python-modules/pysequoia/default.nix

@@ -0,0 +1,61 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitLab
+, pkg-config
+, rustPlatform
+, cargo
+, rustc
+, bzip2
+, nettle
+, openssl
+, pcsclite
+, stdenv
+, darwin
+}:
+
+buildPythonPackage rec {
+  pname = "pysequoia";
+  version = "0.1.14";
+  format = "pyproject";
+
+  src = fetchFromGitLab {
+    owner = "sequoia-pgp";
+    repo = "pysequoia";
+    rev = "v${version}";
+    hash = "sha256-63kUUxZTG33cB/IiD4AiDpLOI6Uew/fETgqhaGc7zp0=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    inherit src;
+    name = "${pname}-${version}";
+    hash = "sha256-S/j3bGgU46nvVQFs35ih05teVEIJrFN4Ryq4B7rLFDE=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    rustPlatform.bindgenHook
+    rustPlatform.cargoSetupHook
+    rustPlatform.maturinBuildHook
+    cargo
+    rustc
+  ];
+
+  buildInputs = [
+    bzip2
+    nettle
+    openssl
+    pcsclite
+  ] ++ lib.optionals stdenv.isDarwin [
+    darwin.apple_sdk.frameworks.CoreFoundation
+    darwin.apple_sdk.frameworks.Security
+  ];
+
+  pythonImportsCheck = [ "pysequoia" ];
+
+  meta = with lib; {
+    description = "This library provides OpenPGP facilities in Python through the Sequoia PGP library";
+    homepage = "https://sequoia-pgp.gitlab.io/pysequoia";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ doronbehar ];
+  };
+}

pkgs/top-level/python-aliases.nix

@@ -291,6 +291,7 @@ mapAliases ({
   scikitimage = scikit-image; # added 2023-05-14
   scikitlearn = scikit-learn; # added 2021-07-21
   selectors34 = throw "selectors34 has been removed: functionality provided by Python itself; archived by upstream."; # added 2021-06-10
+  sequoia = throw "python3Packages.sequoia was replaced by pysequoia - built from a dedicated repository, with a new API."; # added 2023-06-24
   setuptools_scm = setuptools-scm; # added 2021-06-03
   sharkiqpy = sharkiq; # added 2022-05-21
   ssh-mitm = throw "ssh-mitm was removed in favor of the top-level ssh-mitm"; # added 2023-05-09

pkgs/top-level/python-packages.nix

@@ -7785,6 +7785,8 @@ self: super: with self; {
 
   pysbd = callPackage ../development/python-modules/pysbd { };
 
+  pysequoia = callPackage ../development/python-modules/pysequoia { };
+
   pyschemes = callPackage ../development/python-modules/pyschemes { };
 
   pyschlage = callPackage ../development/python-modules/pyschlage { };
@@ -11104,8 +11106,6 @@ self: super: with self; {
 
   seqeval = callPackage ../development/python-modules/seqeval { };
 
-  sequoia = disabledIf isPyPy (toPythonModule pkgs.sequoi);
-
   serialio = callPackage ../development/python-modules/serialio { };
 
   serpent = callPackage ../development/python-modules/serpent { };

pkgs/top-level/python2-packages.nix

@@ -71,8 +71,6 @@ with self; with super; {
 
   scandir = callPackage ../development/python2-modules/scandir { };
 
-  sequoia = disabled super.sequoia;
-
   setuptools = callPackage ../development/python2-modules/setuptools { };
 
   setuptools-scm = callPackage ../development/python2-modules/setuptools-scm { };