Merge pull request #193698 from fee1-dead-contrib/pattypan/new

maintainers/maintainer-list.nix

@@ -4404,6 +4404,12 @@
     name = "Fedx sudo";
     matrix = "fedx:matrix.org";
   };
+  fee1-dead = {
+    email = "ent3rm4n@gmail.com";
+    github = "fee1-dead";
+    githubId = 43851243;
+    name = "Deadbeef";
+  };
   fehnomenal = {
     email = "fehnomenal@fehn.systems";
     github = "fehnomenal";

pkgs/applications/misc/pattypan/default.nix

@@ -0,0 +1,62 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, unzip
+, jre
+, jdk
+, ant
+, makeWrapper
+, makeDesktopItem
+, copyDesktopItems
+, glib
+, wrapGAppsHook
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pattypan";
+  version = "22.03";
+
+  src = fetchFromGitHub {
+    owner = "yarl";
+    repo = "pattypan";
+    rev = "v${version}";
+    sha256 = "0qmvlcqhqw5k500v2xdakk340ymgv5amhbfqxib5s4db1w32pi60";
+  };
+
+  nativeBuildInputs = [ copyDesktopItems jdk ant makeWrapper wrapGAppsHook ];
+  buildInputs = [ glib jre ];
+
+  buildPhase = ''
+    runHook preBuild
+    export JAVA_TOOL_OPTIONS="-Dfile.encoding=UTF8"
+    ant
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin $out/share/java
+    cp pattypan.jar $out/share/java/pattypan.jar
+    makeWrapper ${jre}/bin/java $out/bin/pattypan \
+      --add-flags "-cp $out/share/java/pattypan.jar pattypan.Launcher"
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      desktopName = "Pattypan";
+      genericName = "An uploader for Wikimedia Commons";
+      categories = [ "Utility" ];
+      exec = "pattypan";
+      name = "pattypan";
+    })
+  ];
+
+  meta = with lib; {
+    homepage = "https://commons.wikimedia.org/wiki/Commons:Pattypan";
+    description = "An uploader for Wikimedia Commons";
+    license = licenses.mit;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ fee1-dead ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -28614,6 +28614,8 @@ with pkgs;
 
   moe =  callPackage ../applications/editors/moe { };
 
+  pattypan = callPackage ../applications/misc/pattypan {};
+
   praat = callPackage ../applications/audio/praat { };
 
   quvi = callPackage ../applications/video/quvi/tool.nix {