quickwit: init at 0.6.1

pkgs/servers/search/quickwit/default.nix

@@ -0,0 +1,85 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, rustPlatform
+, nix-update-script
+, protobuf
+, Security
+}:
+
+let
+  pname = "quickwit";
+  version = "0.6.1";
+in
+rustPlatform.buildRustPackage {
+  inherit pname version;
+
+  src = fetchFromGitHub {
+    owner = "quickwit-oss";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-MzPFS1f7AdqfFKSBJHoL0h1nbzRlMJt35msoQ6Ual/Q=";
+  };
+
+  postPatch = ''
+    substituteInPlace ./quickwit-ingest/build.rs \
+      --replace '&[]' '&["."]'
+    substituteInPlace ./quickwit-control-plane/build.rs \
+      --replace '&[]' '&["."]'
+    substituteInPlace ./quickwit-codegen/example/build.rs \
+      --replace '&[]' '&["."]'
+  '';
+
+  sourceRoot = "source/quickwit";
+
+  buildInputs = lib.optionals stdenv.isDarwin [ Security ];
+
+  cargoLock = {
+    lockFile = ./Cargo.lock;
+    outputHashes = {
+      "chitchat-0.5.0" = "sha256-gGWMzTzQNb9JXSbPIanMJpEKhKen1KsIrWQz6wvypDY=";
+      "ownedbytes-0.5.0" = "sha256-+hfp2r/m4Mu+HUXy3gfyU4klHqq+5k363Tpc34IWgLQ=";
+      "path-0.1.0" = "sha256-f+Iix+YuKy45zoQXH7ctzANaL96s7HNUBOhcM1ZV0Ko=";
+      "pulsar-5.0.2" = "sha256-j7wpsAro6x4fk3pvSL4fxLkddJFq8duZ7jDj0Edf3YQ=";
+      "sasl2-sys-0.1.20+2.1.28" = "sha256-u4BsfmTDFxuY3i1amLCsr7MDv356YPThMHclura0Sxs=";
+    };
+  };
+
+  # needed for internal protobuf c wrapper library
+  PROTOC = "${protobuf}/bin/protoc";
+  PROTOC_INCLUDE = "${protobuf}/include";
+
+  passthru.updateScript = nix-update-script { };
+
+  checkFlags = [
+    # tries to make a network access
+    "--skip=test_all_local_index"
+    "--skip=test_cmd_create"
+    "--skip=test_cmd_create_no_index_uri"
+    "--skip=test_cmd_search_aggregation"
+    "--skip=test_cmd_search_with_snippets"
+    "--skip=test_delete_index_cli"
+    "--skip=test_delete_index_cli_dry_run"
+    "--skip=test_ingest_docs_cli"
+    "--skip=test_ingest_docs_cli_keep_cache"
+    "--skip=test_search_index_cli"
+    "--skip=test_garbage_collect_cli_no_grace"
+    "--skip=actors::indexing_service::tests::test_indexing_service_spawn_observe_detach"
+    "--skip=object_storage::s3_compatible_storage::tests::test_s3_compatible_storage_relative_path"
+    # flaky test
+    "--skip=actors::indexer::tests::test_indexer_triggers_commit_on_drained_mailbox"
+    "--skip=actors::indexer::tests::test_indexer_partitioning"
+    "--skip=actors::indexing_pipeline::tests::test_merge_pipeline_does_not_stop_on_indexing_pipeline_failure"
+    # fail on darwin for some reason
+    "--skip=io::tests::test_controlled_writer_limited_async"
+    "--skip=io::tests::test_controlled_writer_limited_sync"
+  ];
+
+  meta = with lib; {
+    description = "Sub-second search & analytics engine on cloud storage";
+    homepage = "https://quickwit.io/";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [ happysalada ];
+    platforms = platforms.all;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -11803,6 +11803,10 @@ with pkgs;
 
   quicktun = callPackage ../tools/networking/quicktun { };
 
+  quickwit = callPackage ../servers/search/quickwit {
+    inherit (darwin.apple_sdk.frameworks) Security;
+  };
+
   quilt = callPackage ../development/tools/quilt { };
 
   raider = callPackage ../applications/misc/raider { };