From 69e19835126e277124aaf84a326a239ad8f5494e Mon Sep 17 00:00:00 2001
From: figsoda <figsoda@pm.me>
Date: Wed, 28 Sep 2022 12:15:28 -0400
Subject: [PATCH] pods: init at 1.0.0-beta.4

---
 .../virtualization/pods/default.nix           | 59 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               | 14 +++++
 2 files changed, 73 insertions(+)
 create mode 100644 pkgs/applications/virtualization/pods/default.nix

diff --git a/pkgs/applications/virtualization/pods/default.nix b/pkgs/applications/virtualization/pods/default.nix
new file mode 100644
index 000000000000..5d811b59066b
--- /dev/null
+++ b/pkgs/applications/virtualization/pods/default.nix
@@ -0,0 +1,59 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, desktop-file-utils
+, glib
+, gtk4
+, meson
+, ninja
+, pkg-config
+, rustPlatform
+, wrapGAppsHook
+, gtksourceview5
+, libadwaita
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pods";
+  version = "1.0.0-beta.4";
+
+  src = fetchFromGitHub {
+    owner = "marhkb";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "1j5rz43860n17qcxmc5dj8sll3y593jj9zz1sfvnx4g0694sp0cl";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    inherit src;
+    name = "${pname}-${version}";
+    sha256 = "sha256-tj0ROO8HmFWyQLYDrdywOneHz6X43dRZJFTB+aw+m7o=";
+  };
+
+  nativeBuildInputs = [
+    desktop-file-utils
+    glib
+    gtk4
+    meson
+    ninja
+    pkg-config
+    rustPlatform.cargoSetupHook
+    rustPlatform.rust.cargo
+    rustPlatform.rust.rustc
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    gtk4
+    gtksourceview5
+    libadwaita
+  ];
+
+  meta = with lib; {
+    description = "A podman desktop application";
+    homepage = "https://github.com/marhkb/pods";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ figsoda ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 670af1827a5b..3195d68d095d 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -10186,6 +10186,20 @@ with pkgs;
 
   podman-tui = callPackage ../applications/virtualization/podman-tui { };
 
+  pods = callPackage ../applications/virtualization/pods {
+    # taken from #182618, remove when merged
+    libadwaita = libadwaita.overrideAttrs (_: rec {
+      version = "1.2.0";
+      src = fetchFromGitLab {
+        domain = "gitlab.gnome.org";
+        owner = "GNOME";
+        repo = "libadwaita";
+        rev = version;
+        hash = "sha256-3lH7Vi9M8k+GSrCpvruRpLrIpMoOakKbcJlaAc/FK+U=";
+      };
+    });
+  };
+
   pod2mdoc = callPackage ../tools/misc/pod2mdoc { };
 
   poedit = callPackage ../tools/text/poedit {