Merge pull request #192391 from mweinelt/whisper

pkgs/development/python-modules/openai-whisper/default.nix

@@ -0,0 +1,64 @@
+{ lib
+, fetchFromGitHub
+, buildPythonPackage
+
+# propagates
+, numpy
+, torch
+, tqdm
+, more-itertools
+, transformers
+, ffmpeg-python
+
+# tests
+, pytestCheckHook
+}:
+
+buildPythonPackage rec {
+  pname = "whisper";
+  version = "unstable-2022-09-23";
+  format = "setuptools";
+
+  src = fetchFromGitHub {
+    owner = "openai";
+    repo = pname;
+    rev = "8cf36f3508c9acd341a45eb2364239a3d81458b9";
+    hash = "sha256-2RH8eM/SezqFJltelv5AjQEGpqXm980u57vrlkTEUvQ=";
+  };
+
+  postPatch = ''
+    # Rely on the ffmpeg path already patched into the ffmpeg-python library
+    substituteInPlace whisper/audio.py \
+      --replace 'run(cmd="ffmpeg",' 'run('
+  '';
+
+  propagatedBuildInputs = [
+    numpy
+    torch
+    tqdm
+    more-itertools
+    transformers
+    ffmpeg-python
+  ];
+
+  preCheck = ''
+    export HOME=$TMPDIR
+  '';
+
+  checkInputs = [
+    pytestCheckHook
+  ];
+
+  disabledTests = [
+    # requires network access to download models
+    "test_transcribe"
+  ];
+
+  meta = with lib; {
+    description = "General-purpose speech recognition model";
+    homepage = "https://github.com/openai/whisper";
+    license = licenses.mit;
+    maintainers = with maintainers; [ hexa ];
+  };
+}
+

pkgs/top-level/all-packages.nix

@@ -17003,6 +17003,8 @@ with pkgs;
 
   openai = with python3Packages; toPythonApplication openai;
 
+  openai-whisper = with python3.pkgs; toPythonApplication openai-whisper;
+
   opengrok = callPackage ../development/tools/misc/opengrok { };
 
   openocd = callPackage ../development/embedded/openocd { };

pkgs/top-level/python-packages.nix

@@ -6378,6 +6378,8 @@ in {
 
   open-meteo = callPackage ../development/python-modules/open-meteo { };
 
+  openai-whisper = callPackage ../development/python-modules/openai-whisper { };
+
   openant = callPackage ../development/python-modules/openant { };
 
   openapi-schema-validator = callPackage ../development/python-modules/openapi-schema-validator { };