From 75fde4130d4caa08561be31cb8e6058fcf71fb07 Mon Sep 17 00:00:00 2001
From: Silvan Mosberger <infinisil@icloud.com>
Date: Fri, 30 Jun 2017 00:03:21 +0200
Subject: [PATCH] scyther: init at 1.1.3

---
 .../science/programming/scyther/default.nix   | 82 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 84 insertions(+)
 create mode 100644 pkgs/applications/science/programming/scyther/default.nix

diff --git a/pkgs/applications/science/programming/scyther/default.nix b/pkgs/applications/science/programming/scyther/default.nix
new file mode 100644
index 000000000000..6e009067e4e4
--- /dev/null
+++ b/pkgs/applications/science/programming/scyther/default.nix
@@ -0,0 +1,82 @@
+{ stdenv, lib, fetchFromGitHub, glibc, flex, bison, python27Packages, graphviz, cmake
+, includeGUI ? true
+, includeProtocols ? true
+}:
+let
+  version = "1.1.3";
+in
+stdenv.mkDerivation {
+  name = "scyther-${version}";
+  src = fetchFromGitHub {
+    rev = "v${version}";
+    sha256 = "0rb4ha5bnjxnwj4f3hciq7kyj96fhw14hqbwl5kr9cdw8q62mx0h";
+    owner = "cascremers";
+    repo = "scyther";
+  };
+
+  buildInputs = [
+    cmake
+    glibc.static
+    flex
+    bison
+  ] ++ lib.optional includeGUI [
+    python27Packages.wrapPython
+  ];
+
+  patchPhase = ''
+    # Since we're not in a git dir, the normal command this project uses to create this file wouldn't work
+    printf "%s\n" "#define TAGVERSION \"${version}\"" > src/version.h
+  '' + lib.optionalString includeGUI ''
+    file=gui/Scyther/Scyther.py
+    
+    # By default the scyther binary is looked for in the directory of the python script ($out/gui), but we want to have it look where our cli package is
+    substituteInPlace $file --replace "return getMyDir()" "return \"$out/bin\""
+
+    # Removes the Shebang from the file, as this would be wrapped wrongly
+    sed -i -e "1d" $file
+  '';
+
+  configurePhase = ''
+    (cd src && cmakeConfigurePhase)
+  '';
+
+  propagatedBuildInputs = lib.optional includeGUI [
+    python27Packages.wxPython
+    graphviz
+  ];
+  
+  dontUseCmakeBuildDir = true;
+  cmakeFlags = [ "-DCMAKE_C_FLAGS=-std=gnu89" ];
+
+  installPhase = ''
+    mkdir -p "$out/bin"
+    cp src/scyther-linux "$out/bin/scyther-cli"
+  '' + lib.optionalString includeGUI ''
+    mkdir -p "$out/gui"
+    cp -r gui/* "$out/gui"
+    ln -s ../gui/scyther-gui.py "$out/bin/scyther-gui"
+    ln -s ../bin/scyther-cli "$out/bin/scyther-linux"
+  '' + lib.optionalString includeProtocols (if includeGUI then ''
+      ln -s ./gui/Protocols "$out/protocols"
+    '' else ''
+      mkdir -p "$out/protocols"
+      cp -r gui/Protocols/* "$out/protocols"
+    '');
+
+  postFixup = lib.optionalString includeGUI ''
+    wrapPythonProgramsIn "$out/gui" "$out $pythonPath"
+  '';
+
+  doInstallCheck = includeGUI;
+  installCheckPhase = ''
+    "$out/gui/scyther.py" "$src/gui/Protocols/Demo/ns3.spdl"
+  '';
+
+  meta = with lib; {
+    description = "Scyther is a tool for the automatic verification of security protocols.";
+    homepage = https://www.cs.ox.ac.uk/people/cas.cremers/scyther/;
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ infinisil ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 593fb7d3a368..9c52320c83e8 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -17852,6 +17852,8 @@ with pkgs;
 
   plm = callPackage ../applications/science/programming/plm { };
 
+  scyther = callPackage_i686 ../applications/science/programming/scyther { };
+
   ### SCIENCE/LOGIC
 
   abc-verifier = callPackage ../applications/science/logic/abc {};