clickgen: init at 1.1.9

pkgs/development/python-modules/clickgen/default.nix

@@ -0,0 +1,46 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, pillow
+, libX11
+, libXcursor
+, libpng
+, python
+}:
+
+buildPythonPackage rec {
+  pname = "clickgen";
+  version = "1.1.9";
+
+  src = fetchFromGitHub {
+    owner = "ful1e5";
+    repo = "clickgen";
+    rev = "v${version}";
+    sha256 = "108f3sbramd3hhs4d84s3i3lbwllfrkvjakjq4gdmbw6xpilvm0l";
+  };
+
+  buildInputs = [ libXcursor libX11 libpng ];
+
+  propagatedBuildInputs = [ pillow ];
+
+  pythonImportsCheck = [ "clickgen" ];
+
+  postInstall = ''
+    install -m644 clickgen/xcursorgen.so $out/${python.sitePackages}/clickgen/xcursorgen.so
+  '';
+
+  # Tests fail with ${bitmap_error}.
+  # Application works normally if tests are disabled
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://github.com/ful1e5/clickgen";
+    description = "The hassle-free cursor building toolbox";
+    longDescription = ''
+      clickgen is API for building X11 and Windows Cursors from
+      .png files. clickgen is using anicursorgen and xcursorgen under the hood.
+    '';
+    license = licenses.mit;
+    maintainers = with maintainers; [ AdsonCicilioti ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -2478,6 +2478,8 @@ with pkgs;
 
   clickclack = callPackage ../tools/misc/clickclack { };
 
+  clickgen = with python3Packages; toPythonApplication clickgen;
+
   clog-cli = callPackage ../development/tools/clog-cli { };
 
   cloud-init = python3.pkgs.callPackage ../tools/virtualization/cloud-init { };

pkgs/top-level/python-packages.nix

@@ -1597,6 +1597,8 @@ in {
 
   click-threading = callPackage ../development/python-modules/click-threading { };
 
+  clickgen = callPackage ../development/python-modules/clickgen { };
+
   clickhouse-cityhash = callPackage ../development/python-modules/clickhouse-cityhash { };
 
   clickhouse-cli = callPackage ../development/python-modules/clickhouse-cli { };