From 886711387b87ad74f8408eadd2068af7793d80fe Mon Sep 17 00:00:00 2001
From: PowerUser64 <blake@blakenorth.net>
Date: Mon, 10 Jul 2023 03:49:23 -0700
Subject: [PATCH] vital: init at 1.5.5

---
 pkgs/applications/audio/vital/default.nix | 67 +++++++++++++++++++++++
 pkgs/top-level/all-packages.nix           |  2 +
 2 files changed, 69 insertions(+)
 create mode 100644 pkgs/applications/audio/vital/default.nix

diff --git a/pkgs/applications/audio/vital/default.nix b/pkgs/applications/audio/vital/default.nix
new file mode 100644
index 000000000000..84c910eecb95
--- /dev/null
+++ b/pkgs/applications/audio/vital/default.nix
@@ -0,0 +1,67 @@
+{ lib
+, stdenv
+, fetchzip
+, autoPatchelfHook
+, makeBinaryWrapper
+
+, alsa-lib
+, libjack2
+, curl
+, xorg
+, libGL
+, freetype
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "vital";
+  version = "1.5.5";
+
+  src = fetchzip {
+    url = "https://builds.vital.audio/VitalAudio/vital/${builtins.replaceStrings ["."] ["_"] finalAttrs.version}/VitalInstaller.zip";
+    hash = "sha256-hCwXSUiBB0YpQ1oN6adLprwAoel6f72tBG5fEb61OCI=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    makeBinaryWrapper
+  ];
+
+  buildInputs = [
+    alsa-lib
+    stdenv.cc.cc.lib
+    libGL
+    xorg.libSM
+    xorg.libICE
+    xorg.libX11
+    freetype
+    libjack2
+  ];
+
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    # copy each output to its destination (individually)
+    mkdir -p $out/{bin,lib/{clap,vst,vst3}}
+    for f in bin/Vital lib/{clap/Vital.clap,vst/Vital.so,vst3/Vital.vst3}; do
+      cp -r $f $out/$f
+    done
+
+    wrapProgram $out/bin/Vital \
+      --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ curl libjack2 ]}"
+
+    runHook postInstall
+  '';
+
+
+  meta = with lib; {
+    description = "Spectral warping wavetable synth";
+    homepage = "https://vital.audio/";
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+    license = with licenses; [ unfree gpl3Plus ];
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ PowerUser64 ];
+    mainProgram = "Vital";
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 139c8be63087..fea3ef0345d5 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -33870,6 +33870,8 @@ with pkgs;
 
   vieb = callPackage ../applications/networking/browsers/vieb { };
 
+  vital = callPackage ../applications/audio/vital { };
+
   vivaldi = callPackage ../applications/networking/browsers/vivaldi { };
 
   vivaldi-ffmpeg-codecs = callPackage ../applications/networking/browsers/vivaldi/ffmpeg-codecs.nix { };