Pontus Stenetorp
parent
7f5bf274d1
commit
a0b0f99458
3 changed files with 1 additions and 166 deletions
|
|
@ -1,161 +0,0 @@
|
||||||
{ lib, stdenv, fetchurl, fetchzip, fetchFromGitHub
|
|
||||||
# build tools
|
|
||||||
, gfortran, m4, makeWrapper, patchelf, perl, which, python2
|
|
||||||
, cmake
|
|
||||||
# libjulia dependencies
|
|
||||||
, libunwind, readline, utf8proc, zlib
|
|
||||||
# standard library dependencies
|
|
||||||
, curl, fftwSinglePrec, fftw, gmp, libgit2, mpfr, openlibm, openspecfun, pcre2
|
|
||||||
# linear algebra
|
|
||||||
, blas, lapack, arpack
|
|
||||||
# Darwin frameworks
|
|
||||||
, CoreServices, ApplicationServices
|
|
||||||
}:
|
|
||||||
|
|
||||||
assert (!blas.isILP64) && (!lapack.isILP64);
|
|
||||||
|
|
||||||
with lib;
|
|
||||||
|
|
||||||
let
|
|
||||||
majorVersion = "1";
|
|
||||||
minorVersion = "3";
|
|
||||||
maintenanceVersion = "1";
|
|
||||||
src_sha256 = "0q9a7yc3b235psrwl5ghyxgwly25lf8n818l8h6bkf2ymdbsv5p6";
|
|
||||||
version = "${majorVersion}.${minorVersion}.${maintenanceVersion}";
|
|
||||||
in
|
|
||||||
|
|
||||||
stdenv.mkDerivation rec {
|
|
||||||
pname = "julia";
|
|
||||||
inherit version;
|
|
||||||
|
|
||||||
src = fetchzip {
|
|
||||||
url = "https://github.com/JuliaLang/julia/releases/download/v${majorVersion}.${minorVersion}.${maintenanceVersion}/julia-${majorVersion}.${minorVersion}.${maintenanceVersion}-full.tar.gz";
|
|
||||||
sha256 = src_sha256;
|
|
||||||
};
|
|
||||||
|
|
||||||
prePatch = ''
|
|
||||||
export PATH=$PATH:${cmake}/bin
|
|
||||||
'';
|
|
||||||
|
|
||||||
patches = [
|
|
||||||
./use-system-utf8proc-julia-1.3.patch
|
|
||||||
|
|
||||||
# Julia recompiles a precompiled file if the mtime stored *in* the
|
|
||||||
# .ji file differs from the mtime of the .ji file. This
|
|
||||||
# doesn't work in Nix because Nix changes the mtime of files in
|
|
||||||
# the Nix store to 1. So patch Julia to accept mtimes of 1.
|
|
||||||
./allow_nix_mtime.patch
|
|
||||||
];
|
|
||||||
|
|
||||||
postPatch = ''
|
|
||||||
patchShebangs . contrib
|
|
||||||
for i in backtrace cmdlineargs; do
|
|
||||||
mv test/$i.jl{,.off}
|
|
||||||
touch test/$i.jl
|
|
||||||
done
|
|
||||||
rm stdlib/Sockets/test/runtests.jl && touch stdlib/Sockets/test/runtests.jl
|
|
||||||
rm stdlib/Distributed/test/runtests.jl && touch stdlib/Distributed/test/runtests.jl
|
|
||||||
sed -e 's/Invalid Content-Type:/invalid Content-Type:/g' -i ./stdlib/LibGit2/test/libgit2.jl
|
|
||||||
sed -e 's/Failed to resolve /failed to resolve /g' -i ./stdlib/LibGit2/test/libgit2.jl
|
|
||||||
'';
|
|
||||||
|
|
||||||
buildInputs = [
|
|
||||||
arpack fftw fftwSinglePrec gmp libgit2 libunwind mpfr
|
|
||||||
pcre2.dev blas lapack openlibm openspecfun readline utf8proc
|
|
||||||
zlib
|
|
||||||
]
|
|
||||||
++ lib.optionals stdenv.isDarwin [CoreServices ApplicationServices]
|
|
||||||
;
|
|
||||||
|
|
||||||
nativeBuildInputs = [ curl gfortran m4 makeWrapper patchelf perl python2 which ];
|
|
||||||
|
|
||||||
makeFlags =
|
|
||||||
let
|
|
||||||
arch = head (splitString "-" stdenv.system);
|
|
||||||
march = {
|
|
||||||
x86_64 = stdenv.hostPlatform.gcc.arch or "x86-64";
|
|
||||||
i686 = "pentium4";
|
|
||||||
aarch64 = "armv8-a";
|
|
||||||
}.${arch}
|
|
||||||
or (throw "unsupported architecture: ${arch}");
|
|
||||||
# Julia requires Pentium 4 (SSE2) or better
|
|
||||||
cpuTarget = { x86_64 = "x86-64"; i686 = "pentium4"; aarch64 = "generic"; }.${arch}
|
|
||||||
or (throw "unsupported architecture: ${arch}");
|
|
||||||
in [
|
|
||||||
"ARCH=${arch}"
|
|
||||||
"MARCH=${march}"
|
|
||||||
"JULIA_CPU_TARGET=${cpuTarget}"
|
|
||||||
"PREFIX=$(out)"
|
|
||||||
"prefix=$(out)"
|
|
||||||
"SHELL=${stdenv.shell}"
|
|
||||||
|
|
||||||
(lib.optionalString (!stdenv.isDarwin) "USE_SYSTEM_BLAS=1")
|
|
||||||
"USE_BLAS64=${if blas.isILP64 then "1" else "0"}"
|
|
||||||
|
|
||||||
"USE_SYSTEM_LAPACK=1"
|
|
||||||
|
|
||||||
"USE_SYSTEM_ARPACK=1"
|
|
||||||
"USE_SYSTEM_FFTW=1"
|
|
||||||
"USE_SYSTEM_GMP=1"
|
|
||||||
"USE_SYSTEM_LIBGIT2=1"
|
|
||||||
"USE_SYSTEM_LIBUNWIND=1"
|
|
||||||
|
|
||||||
"USE_SYSTEM_MPFR=1"
|
|
||||||
"USE_SYSTEM_OPENLIBM=1"
|
|
||||||
"USE_SYSTEM_OPENSPECFUN=1"
|
|
||||||
"USE_SYSTEM_PATCHELF=1"
|
|
||||||
"USE_SYSTEM_PCRE=1"
|
|
||||||
"PCRE_CONFIG=${pcre2.dev}/bin/pcre2-config"
|
|
||||||
"PCRE_INCL_PATH=${pcre2.dev}/include/pcre2.h"
|
|
||||||
"USE_SYSTEM_READLINE=1"
|
|
||||||
"USE_SYSTEM_UTF8PROC=1"
|
|
||||||
"USE_SYSTEM_ZLIB=1"
|
|
||||||
|
|
||||||
"USE_BINARYBUILDER=0"
|
|
||||||
];
|
|
||||||
|
|
||||||
LD_LIBRARY_PATH = makeLibraryPath [
|
|
||||||
arpack fftw fftwSinglePrec gmp libgit2 mpfr blas openlibm
|
|
||||||
openspecfun pcre2 lapack
|
|
||||||
];
|
|
||||||
|
|
||||||
# Other versions of Julia pass the tests, but we are not sure why these fail.
|
|
||||||
doCheck = false;
|
|
||||||
checkTarget = "testall";
|
|
||||||
# Julia's tests require read/write access to $HOME
|
|
||||||
preCheck = ''
|
|
||||||
export HOME="$NIX_BUILD_TOP"
|
|
||||||
'';
|
|
||||||
|
|
||||||
preBuild = ''
|
|
||||||
sed -e '/^install:/s@[^ ]*/doc/[^ ]*@@' -i Makefile
|
|
||||||
sed -e '/[$](DESTDIR)[$](docdir)/d' -i Makefile
|
|
||||||
export LD_LIBRARY_PATH=${LD_LIBRARY_PATH}
|
|
||||||
'';
|
|
||||||
|
|
||||||
postInstall = ''
|
|
||||||
# Symlink shared libraries from LD_LIBRARY_PATH into lib/julia,
|
|
||||||
# as using a wrapper with LD_LIBRARY_PATH causes segmentation
|
|
||||||
# faults when program returns an error:
|
|
||||||
# $ julia -e 'throw(Error())'
|
|
||||||
find $(echo $LD_LIBRARY_PATH | sed 's|:| |g') -maxdepth 1 -name '*.${if stdenv.isDarwin then "dylib" else "so"}*' | while read lib; do
|
|
||||||
if [[ ! -e $out/lib/julia/$(basename $lib) ]]; then
|
|
||||||
ln -sv $lib $out/lib/julia/$(basename $lib)
|
|
||||||
fi
|
|
||||||
done
|
|
||||||
'';
|
|
||||||
|
|
||||||
passthru = {
|
|
||||||
inherit majorVersion minorVersion maintenanceVersion;
|
|
||||||
site = "share/julia/site/v${majorVersion}.${minorVersion}";
|
|
||||||
};
|
|
||||||
|
|
||||||
meta = {
|
|
||||||
description = "High-level performance-oriented dynamical language for technical computing";
|
|
||||||
homepage = "https://julialang.org/";
|
|
||||||
license = lib.licenses.mit;
|
|
||||||
maintainers = with lib.maintainers; [ raskin rob garrison ];
|
|
||||||
platforms = [ "i686-linux" "x86_64-linux" "x86_64-darwin" ];
|
|
||||||
broken = stdenv.isi686;
|
|
||||||
};
|
|
||||||
}
|
|
||||||
|
|
@ -339,6 +339,7 @@ mapAliases ({
|
||||||
jellyfin_10_5 = throw "Jellyfin 10.5 is no longer supported and contains a security vulnerability. Please upgrade to a newer version."; # added 2021-04-26
|
jellyfin_10_5 = throw "Jellyfin 10.5 is no longer supported and contains a security vulnerability. Please upgrade to a newer version."; # added 2021-04-26
|
||||||
julia_07 = throw "julia_07 is deprecated in favor of julia_10 LTS"; # added 2020-09-15
|
julia_07 = throw "julia_07 is deprecated in favor of julia_10 LTS"; # added 2020-09-15
|
||||||
julia_11 = throw "julia_11 is deprecated in favor of latest Julia version"; # added 2020-09-15
|
julia_11 = throw "julia_11 is deprecated in favor of latest Julia version"; # added 2020-09-15
|
||||||
|
julia_13 = throw "julia_13 is deprecated in favor of the latest stable version"; # added 2021-03-13
|
||||||
kdeconnect = plasma5Packages.kdeconnect-kde; # added 2020-10-28
|
kdeconnect = plasma5Packages.kdeconnect-kde; # added 2020-10-28
|
||||||
kdiff3-qt5 = kdiff3; # added 2017-02-18
|
kdiff3-qt5 = kdiff3; # added 2017-02-18
|
||||||
keepass-keefox = keepass-keepassrpc; # backwards compatibility alias, added 2018-02
|
keepass-keefox = keepass-keepassrpc; # backwards compatibility alias, added 2018-02
|
||||||
|
|
|
||||||
|
|
@ -10985,11 +10985,6 @@ in
|
||||||
libgit2 = libgit2_0_27;
|
libgit2 = libgit2_0_27;
|
||||||
};
|
};
|
||||||
|
|
||||||
julia_13 = callPackage ../development/compilers/julia/1.3.nix {
|
|
||||||
gmp = gmp6;
|
|
||||||
inherit (darwin.apple_sdk.frameworks) CoreServices ApplicationServices;
|
|
||||||
};
|
|
||||||
|
|
||||||
julia_15 = callPackage ../development/compilers/julia/1.5.nix {
|
julia_15 = callPackage ../development/compilers/julia/1.5.nix {
|
||||||
inherit (darwin.apple_sdk.frameworks) CoreServices ApplicationServices;
|
inherit (darwin.apple_sdk.frameworks) CoreServices ApplicationServices;
|
||||||
};
|
};
|
||||||
|
|
|
||||||
Loading…
Reference in a new issue