platformsh: 3.79.2 -> 4.10.0

Also:
- Follow the rename of the repository
- Switch to the new composer builder

pkgs/by-name/pl/platformsh/package.nix

@@ -0,0 +1,42 @@
+{ common-updater-scripts, curl, fetchFromGitHub, jq, lib, php, writeShellScript }:
+
+php.buildComposerProject (finalAttrs: {
+  pname = "platformsh";
+  version = "4.10.0";
+
+  src = fetchFromGitHub {
+    owner = "platformsh";
+    repo = "legacy-cli";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-aEQxlotwMScEIfHrVDdXBgFxMqAIypkEl9TLi1Bvhnw=";
+  };
+
+  vendorHash = "sha256-e89xxgTI6FajDfj8xr8VYlbxJD6lUZWz5+2UFQTClsY=";
+
+  prePatch = ''
+    substituteInPlace config-defaults.yaml \
+      --replace "@version-placeholder@" "${finalAttrs.version}"
+  '';
+
+  passthru.updateScript = writeShellScript "update-${finalAttrs.pname}" ''
+    set -o errexit
+    export PATH="${lib.makeBinPath [ curl jq common-updater-scripts ]}"
+    NEW_VERSION=$(curl -s https://api.github.com/repos/platformsh/legacy-cli/releases/latest | jq .tag_name --raw-output)
+
+    if [[ "v${finalAttrs.version}" = "$NEW_VERSION" ]]; then
+      echo "The new version same as the old version."
+      exit 0
+    fi
+
+    update-source-version "platformsh" "$NEW_VERSION"
+  '';
+
+  meta = {
+    description = "The unified tool for managing your Platform.sh services from the command line.";
+    homepage = "https://github.com/platformsh/legacy-cli";
+    license = lib.licenses.mit;
+    mainProgram = "platform";
+    maintainers = with lib.maintainers; [ shyim ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/misc/platformsh/default.nix

@@ -1,51 +0,0 @@
-{ stdenv, fetchurl, makeWrapper, writeShellScript, lib, php, curl, jq, common-updater-scripts }:
-
-let
-  pname = "platformsh";
-  version = "3.79.2";
-in
-stdenv.mkDerivation {
-  inherit pname version;
-
-  src = fetchurl {
-    url = "https://github.com/platformsh/platformsh-cli/releases/download/v${version}/platform.phar";
-    sha256 = "sha256-STGMKWgI4C6ccg8DGUhdnEENOB2//gtpU0ljM4cQCXI=";
-  };
-
-  dontUnpack = true;
-
-  nativeBuildInputs = [ makeWrapper ];
-
-  installPhase = ''
-    runHook preInstall
-    mkdir -p $out/bin
-    install -D $src $out/libexec/platformsh/platform.phar
-    makeWrapper ${php}/bin/php $out/bin/platform \
-      --add-flags "$out/libexec/platformsh/platform.phar"
-    runHook postInstall
-  '';
-
-  passthru = {
-      updateScript = writeShellScript "update-${pname}" ''
-        set -o errexit
-        export PATH="${lib.makeBinPath [ curl jq common-updater-scripts ]}"
-        NEW_VERSION=$(curl -s https://api.github.com/repos/platformsh/platformsh-cli/releases/latest | jq .tag_name --raw-output)
-
-        if [[ "v${version}" = "$NEW_VERSION" ]]; then
-            echo "The new version same as the old version."
-            exit 0
-        fi
-
-        update-source-version "platformsh" "$NEW_VERSION"
-      '';
-    };
-
-  meta = with lib; {
-    description = "The unified tool for managing your Platform.sh services from the command line.";
-    homepage = "https://github.com/platformsh/platformsh-cli";
-    license = licenses.mit;
-    maintainers = with maintainers; [ shyim ];
-    mainProgram = "platform";
-    platforms = platforms.all;
-  };
-}

pkgs/top-level/all-packages.nix

@@ -4016,8 +4016,6 @@ with pkgs;
 
   pdepend = callPackage ../development/php-packages/pdepend { };
 
-  platformsh = callPackage ../misc/platformsh { };
-
   inherd-quake = callPackage ../applications/misc/inherd-quake {
     inherit (darwin.apple_sdk.frameworks) CoreServices Security;
   };