cafkafk/nixpkgs
cafkafk/nixpkgs
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 2

mpvScripts.video-cutter: init at unstable-2021-02-03

Browse source
This commit is contained in:
legendofmiracles 2021-11-21 15:40:15 -06:00 committed by Jonathan Ringer
parent ab7d727c97
commit c85680db4f
2 changed files with 48 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

47
pkgs/applications/video/mpv/scripts/cutter.nix Normal file
View file

@ -0,0 +1,47 @@
{ lib, stdenvNoCC, fetchFromGitHub, makeWrapper }:
stdenvNoCC.mkDerivation {
pname = "video-cutter";
version = "unstable-2021-02-03";
src = fetchFromGitHub {
owner = "rushmj";
repo = "mpv-video-cutter";
rev = "718d6ce9356e63fdd47208ec44f575a212b9068a";
sha256 = "sha256-ramID1DPl0UqEzevpqdYKb9aaW3CAy3Dy9CPb/oJ4eY=";
};
dontBuild = true;
dontCheck = true;
nativeBuildInputs = [ makeWrapper ];
postPatch = ''
substituteInPlace cutter.lua \
--replace '~/.config/mpv/scripts/c_concat.sh' '${placeholder "out"}/share/mpv/scripts/c_concat.sh'
# needs to be ran separately so that we can replace everything, and not every single mention explicitly
# original script places them in the scripts folder, just spawning unnecessary errors
# i know that hardcoding .config and especially the .mpv directory isn't best practice, but I didn't want to deviate too much from upstream
substituteInPlace cutter.lua \
--replace '~/.config/mpv/scripts' "''${XDG_CONFIG_HOME:-~/.config}/mpv/cutter"
'';
installPhase = ''
install -Dm755 c_concat.sh $out/share/mpv/scripts/c_concat.sh
install cutter.lua $out/share/mpv/scripts/cutter.lua
wrapProgram $out/share/mpv/scripts/c_concat.sh \
--run "mkdir -p ~/.config/mpv/cutter/"
'';
passthru.scriptName = "cutter.lua";
meta = with lib; {
description = "Cut videos and concat them automatically";
homepage = "https://github.com/rushmj/mpv-video-cutter";
# repo doesn't have a license
license = licenses.unfree;
maintainers = with maintainers; [ legendofmiracles ];
};
}

1
pkgs/top-level/all-packages.nix
View file

@ -26963,6 +26963,7 @@ with pkgs;
sponsorblock = callPackage ../applications/video/mpv/scripts/sponsorblock.nix {};
thumbnail = callPackage ../applications/video/mpv/scripts/thumbnail.nix { };
youtube-quality = callPackage ../applications/video/mpv/scripts/youtube-quality.nix { };
cutter = callPackage ../applications/video/mpv/scripts/cutter.nix { };
};
mrpeach = callPackage ../applications/audio/pd-plugins/mrpeach { };