Merge pull request #137230 from figsoda/menyoki

pkgs/applications/graphics/menyoki/default.nix

@@ -0,0 +1,44 @@
+{ fetchFromGitHub
+, installShellFiles
+, lib
+, pkg-config
+, rustPlatform
+, stdenv
+, libX11
+, libXrandr
+, withSki ? true
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "menyoki";
+  version = "1.5.3";
+
+  src = fetchFromGitHub {
+    owner = "orhun";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "050c6c60il6cy0a8d3nw4z2cyp043912a7n4n44yjpmx047w7kc7";
+  };
+
+  cargoSha256 = "0wwcda2w8jg3q132cvhdgfmjc0rz93fx6fai93g5w8br98aq9qzx";
+
+  nativeBuildInputs = [ installShellFiles ]
+    ++ lib.optional stdenv.isLinux pkg-config;
+
+  buildInputs = lib.optionals stdenv.isLinux [ libX11 libXrandr ];
+
+  cargoBuildFlags = lib.optional (!withSki) "--no-default-features";
+
+  postInstall = ''
+    installManPage man/*
+    installShellCompletion completions/menyoki.{bash,fish,zsh}
+  '';
+
+  meta = with lib; {
+    description = "Screen{shot,cast} and perform ImageOps on the command line";
+    homepage = "https://menyoki.cli.rs/";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ figsoda ];
+    broken = stdenv.isDarwin;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -26133,6 +26133,10 @@ with pkgs;
 
   menumaker = callPackage ../applications/misc/menumaker { };
 
+  menyoki = callPackage ../applications/graphics/menyoki {
+    inherit (xorg) libX11 libXrandr;
+  };
+
   mercurial_4 = callPackage ../applications/version-management/mercurial/4.9.nix {
     inherit (darwin.apple_sdk.frameworks) ApplicationServices;
   };