python3Packages.manimpango: init at 0.3.1

pkgs/development/python-modules/manimpango/default.nix

@@ -0,0 +1,37 @@
+{ stdenv, lib, buildPythonPackage, fetchFromGitHub, python, pkg-config, pango, cython, AppKit, pytestCheckHook }:
+
+buildPythonPackage rec {
+  pname = "manimpango";
+  version = "0.3.1";
+
+  src = fetchFromGitHub {
+    owner = "ManimCommunity";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "ldZfvv5kloQ0uj0agxOP8cRh+Ix8f9Z0PT+pnhWYjiQ=";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.cfg --replace "--cov --no-cov-on-fail" ""
+  '';
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ pango ] ++ lib.optionals stdenv.isDarwin [ AppKit ];
+  propagatedBuildInputs = [
+    cython
+  ];
+
+  preBuild = ''
+    ${python.interpreter} setup.py build_ext --inplace
+  '';
+
+  checkInputs = [ pytestCheckHook ];
+  pythonImportsCheck = [ "manimpango" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/ManimCommunity/ManimPango";
+    license = licenses.gpl3Plus;
+    description = "Binding for Pango";
+    maintainers = [ maintainers.angustrau ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -4581,6 +4581,10 @@ in {
 
   manhole = callPackage ../development/python-modules/manhole { };
 
+  manimpango = callPackage ../development/python-modules/manimpango {
+    inherit (pkgs.darwin.apple_sdk.frameworks) AppKit;
+  };
+
   manifestparser = callPackage ../development/python-modules/marionette-harness/manifestparser.nix { };
 
   manuel = callPackage ../development/python-modules/manuel { };