diff --git a/pkgs/development/tools/schemacrawler/default.nix b/pkgs/development/tools/schemacrawler/default.nix
new file mode 100644
index 000000000000..7db69d7a1561
--- /dev/null
+++ b/pkgs/development/tools/schemacrawler/default.nix
@@ -0,0 +1,42 @@
+{ lib
+, stdenv
+, fetchzip
+, jre
+, makeWrapper
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "schemacrawler";
+  version = "16.20.4";
+
+  src = fetchzip {
+    url = "https://github.com/schemacrawler/SchemaCrawler/releases/download/v${finalAttrs.version}/schemacrawler-${finalAttrs.version}-bin.zip";
+    hash = "sha256-wNvFutxB34gjBCwVPIj/5jjjk0/IjH0EbD++FxxuweM=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp -r {config,lib} $out/
+
+    makeWrapper ${jre}/bin/java $out/bin/schemacrawler \
+      --add-flags "-cp $out/lib/*:$out/config" \
+      --add-flags schemacrawler.Main
+
+    runHook postInstall
+  '';
+
+  preferLocalBuild = true;
+
+  meta = with lib; {
+    description = "Database schema discovery and comprehension tool";
+    homepage = "https://www.schemacrawler.com/";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = with licenses; [ epl10 gpl3Only lgpl3Only ];
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ elohmeier ];
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 2639afba28ae..fda8733d69b7 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -12851,6 +12851,8 @@ with pkgs;
 
   schema2ldif = callPackage ../tools/text/schema2ldif { };
 
+  schemacrawler = callPackage ../development/tools/schemacrawler { };
+
   sharedown = callPackage ../tools/misc/sharedown { };
 
   shen-sbcl = callPackage ../development/interpreters/shen-sbcl { };