openmw: add darwin support

The OpenMW codebase already has Darwin build support within it, so porting
it over to nixpkgs was something I wanted to try out.

Issues encountered, in order:

A few dependencies in nixpkgs were missing Darwin support. Details of those
changes are in their respective commits.

After the dependencies were building, the build first failed with a missing
reference to VideoDecodeAcceleration, which was easily dealt with.

Then the build succeeded! Job's done, success! Except OpenMW.app was nowhere
to be found in the result folder. OpenMW-CS.app, however, was produced and
appeared to be running correctly (though I will admit I didn't test it very
much as I'm not very familiar).

Going through OpenMW's CMakeLists.txt showed that a CMake define was needed,
`OPENMW_OSX_DEPLOYMENT=ON`. This is what enables OpenMW.app to be built.

Once the define was added, the build began to fail with missing plugins to
OpenSceneGraph. Looking into that showed that OSG doesn't build certain plugins
on Darwin due to the fact that their functionality is replicated by built-
in system libraries. To save space, these libraries are not built on Darwin.

OpenMW, however, requires these libraries to exist. I was familiar with the
process of building OpenMW on Darwin already, due to having built it locally
ahead of time, so I remembered that the OpenMW folks have a separate repository
with Mac-specific patches. One of those patches is to OpenSceneGraph for this
exact issue, which is now applied here.

The next error was caused by `fixup_bundle` running from the OpenMW CMakeLists.txt,
which appears to be broken in Darwin under Nix. Searching nixpkgs shows that others
have worked around the issue by removing the call to `fixup_bundle` completely.

At this point, the build passed and OpenMW.app was created and was executable!
After the intro video played, it was clear that something wasn't working though.
Every texture was completely pink, navigating the main menu was impossible. Looking
at the console output showed that OpenSceneGraph was attempting to load dds
textures, but the plugin for doing so could not be loaded. I looked at the plugin
with `file` which showed the file was actually a bash script. It was setting
some QT environment variables before calling the real plugin executable. I
resolved this issue with setting `dontWrapQtApps`, as everything seems to work
without it (even the QT-based apps like the Construction Set).

pkgs/games/openmw/default.nix

@@ -1,4 +1,5 @@
 { lib
+, stdenv
 , mkDerivation
 , fetchFromGitHub
 , fetchpatch
@@ -16,6 +17,7 @@
 , libXt
 , lz4
 , recastnavigation
+, VideoDecodeAcceleration
 }:
 
 let
@@ -27,6 +29,15 @@ let
         rev = "bbe61c3bc510a4f5bb4aea21cce506519c2d24e6";
         sha256 = "sha256-t3smLqstp7wWfi9HXJoBCek+3acqt/ySBYF8RJOG6Mo=";
       };
+      patches = [
+        (fetchpatch {
+          # For Darwin, OSG doesn't build some plugins as they're redundant with QuickTime.
+          # OpenMW doesn't like this, and expects them to be there. Apply their patch for it.
+          name = "darwin-osg-plugins-fix.patch";
+          url = "https://gitlab.com/OpenMW/openmw-dep/-/raw/0abe3c9c3858211028d881d7706813d606335f72/macos/osg.patch";
+          sha256 = "sha256-/CLRZofZHot8juH78VG1/qhTHPhy5DoPMN+oH8hC58U=";
+        })
+      ];
     });
 
   bullet_openmw = bullet.overrideDerivation (old: rec {
@@ -65,10 +76,16 @@ mkDerivation rec {
 
   postPatch = ''
     sed '1i#include <memory>' -i components/myguiplatform/myguidatamanager.cpp # gcc12
+  '' + lib.optionalString stdenv.isDarwin ''
+    # Don't fix Darwin app bundle
+    sed -i '/fixup_bundle/d' CMakeLists.txt
   '';
 
   nativeBuildInputs = [ cmake pkg-config wrapQtAppsHook ];
 
+  # If not set, OSG plugin .so files become shell scripts on Darwin.
+  dontWrapQtApps = true;
+
   buildInputs = [
     SDL2
     boost
@@ -81,12 +98,16 @@ mkDerivation rec {
     unshield
     lz4
     recastnavigation
+  ] ++ lib.optionals stdenv.isDarwin [
+    VideoDecodeAcceleration
   ];
 
   cmakeFlags = [
     # as of 0.46, openmw is broken with GLVND
     "-DOpenGL_GL_PREFERENCE=LEGACY"
     "-DOPENMW_USE_SYSTEM_RECASTNAVIGATION=1"
+  ] ++ lib.optionals stdenv.isDarwin [
+    "-DOPENMW_OSX_DEPLOYMENT=ON"
   ];
 
   meta = with lib; {
@@ -94,6 +115,6 @@ mkDerivation rec {
     homepage = "https://openmw.org";
     license = licenses.gpl3Plus;
     maintainers = with maintainers; [ abbradar marius851000 ];
-    platforms = platforms.linux;
+    platforms = platforms.linux ++ platforms.darwin;
   };
 }

pkgs/top-level/all-packages.nix

@@ -35797,7 +35797,9 @@ with pkgs;
 
   openloco = pkgsi686Linux.callPackage ../games/openloco { };
 
-  openmw = libsForQt5.callPackage ../games/openmw { };
+  openmw = libsForQt5.callPackage ../games/openmw {
+    inherit (darwin.apple_sdk.frameworks) VideoDecodeAcceleration;
+  };
 
   openmw-tes3mp = libsForQt5.callPackage ../games/openmw/tes3mp.nix { };