muparser: 2.2.3 -> 2.3.4, refactor

pkgs/by-name/mu/muparser/package.nix

@@ -0,0 +1,40 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, llvmPackages
+}:
+
+stdenv.mkDerivation rec {
+  pname = "muparser";
+  version = "2.3.4";
+
+  src = fetchFromGitHub {
+    owner = "beltoforion";
+    repo = "muparser";
+    rev = "v${version}";
+    hash = "sha256-hutmmhw7BHAwbDKBiK+3Yw833GL0rPGlVjlO7XzTii0=";
+  };
+
+  postPatch = ''
+    substituteInPlace muparser.pc.in \
+      --replace "\''${prefix}/@CMAKE_INSTALL_LIBDIR@" "@CMAKE_INSTALL_FULL_LIBDIR@" \
+      --replace "\''${prefix}/@CMAKE_INSTALL_INCLUDEDIR@" "@CMAKE_INSTALL_FULL_INCLUDEDIR@"
+  '';
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = lib.optionals stdenv.cc.isClang [
+    llvmPackages.openmp
+  ];
+
+  meta = {
+    description = "An extensible high performance math expression parser library written in C++";
+    homepage = "https://beltoforion.de/en/muparser/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ wegank ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/development/libraries/muparser/default.nix

@@ -1,22 +0,0 @@
-{lib, stdenv, fetchurl, unzip, setfile}:
-
-stdenv.mkDerivation rec {
-  pname = "muparser";
-  version = "2.2.3";
-  url-version = lib.replaceStrings ["."] ["_"] version;
-
-  src = fetchurl {
-    url = "mirror://sourceforge/muparser/muparser_v${url-version}.zip";
-    sha256 = "00l92k231yb49wijzkspa2l58mapn6vh2dlxnlg0pawjjfv33s6z";
-  };
-
-  nativeBuildInputs = [ unzip ];
-  buildInputs = lib.optionals stdenv.isDarwin [setfile];
-
-  meta = {
-    homepage = "http://muparser.sourceforge.net";
-    description = "An extensible high performance math expression parser library written in C++";
-    license = lib.licenses.mit;
-    platforms = lib.platforms.linux ++ lib.platforms.darwin;
-  };
-}

pkgs/top-level/all-packages.nix

@@ -24063,10 +24063,6 @@ with pkgs;
 
   mujoco = callPackage ../applications/science/robotics/mujoco { };
 
-  muparser = callPackage ../development/libraries/muparser {
-    inherit (darwin.stubs) setfile;
-  };
-
   muparserx = callPackage ../development/libraries/muparserx { };
 
   mutest = callPackage ../development/libraries/mutest { };