eb04659fc2
This was achieved using the following command:
sd 'wrapGAppsHook\b' wrapGAppsHook3 (rg -l 'wrapGAppsHook\b')
And then manually reverted the following changes:
- alias in top-level.nix
- function name in wrap-gapps-hook.sh
- comment in postFixup of at-spi2-core
- comment in gtk4
- comment in preFixup of 1password-gui/linux.nix
- comment in postFixup of qgis/unwrapped-ltr.nix and qgis/unwrapped.nix
- comment in postFixup of telegram-desktop
- comment in postFixup of fwupd
- buildCommand of mongodb-compass
- postFixup of xflux-gui
- comment in a patch in kdePackages.kde-gtk-config and plasma5Packages.kde-gtk-config
- description of programs.sway.wrapperFeatures.gtk NixOS option (manual rebuild)
62 lines
1.8 KiB
Nix
62 lines
1.8 KiB
Nix
{ lib, stdenv, fetchurl, gettext, coreutils, gnused, gnome
|
|
, gnugrep, parted, glib, libuuid, pkg-config, gtkmm3, libxml2
|
|
, gpart, hdparm, procps, util-linux, polkit, wrapGAppsHook3, substituteAll
|
|
, mtools, dosfstools
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "gparted";
|
|
version = "1.6.0";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/gparted/${pname}-${version}.tar.gz";
|
|
sha256 = "sha256-m59Rs85JTdy1mlXhrmZ5wJQ2YE4zHb9aU21g3tbG6ls=";
|
|
};
|
|
|
|
# Tries to run `pkexec --version` to get version.
|
|
# however the binary won't be suid so it returns
|
|
# an error preventing the program from detection
|
|
patches = [
|
|
(substituteAll {
|
|
src = ./polkit.patch;
|
|
polkit_version = polkit.version;
|
|
})
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
configureFlags = [ "--disable-doc" ];
|
|
|
|
buildInputs = [ parted glib libuuid gtkmm3 libxml2 polkit.bin gnome.adwaita-icon-theme ];
|
|
nativeBuildInputs = [ gettext pkg-config wrapGAppsHook3 ];
|
|
|
|
preConfigure = ''
|
|
# For ITS rules
|
|
addToSearchPath "XDG_DATA_DIRS" "${polkit.out}/share"
|
|
'';
|
|
|
|
preFixup = ''
|
|
gappsWrapperArgs+=(
|
|
--prefix PATH : "${lib.makeBinPath [ gpart hdparm util-linux procps coreutils gnused gnugrep mtools dosfstools ]}"
|
|
)
|
|
'';
|
|
|
|
# Doesn't get installed automaticallly if PREFIX != /usr
|
|
postInstall = ''
|
|
install -D -m0644 org.gnome.gparted.policy \
|
|
$out/share/polkit-1/actions/org.gnome.gparted.policy
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Graphical disk partitioning tool";
|
|
longDescription = ''
|
|
GNOME Partition Editor for creating, reorganizing, and deleting disk
|
|
partitions. GParted enables you to change the partition organization
|
|
while preserving the partition contents.
|
|
'';
|
|
homepage = "https://gparted.org";
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.linux;
|
|
mainProgram = "gparted";
|
|
};
|
|
}
|