90872e2b6c
Consider this as a first step towards the integration of Qt5 into nixpkgs, it does not yet intends to replace Qt4 on every packages even if possible. My goal here is to have a first derivation in common between people who needs qt5 for development purposes. The derivation has been written from scratch but I took care to read at the version 4 to re-integrate some patches which are still compatible. However, I did not had enough time to test gtkStyle and flashplayerFix as I do not use any of them. Also, OSX users will have to do some extra work because I do not have any mac. Finally, as some configure flags have changed and in an hope to provide a clear package definition before it becomes mature, I voluntary added some flags which are default. Once every option will be mastered, we will just have to redo a pass on qt5 configure flags and remove the ones which are set by default.
157 lines
4.5 KiB
Nix
157 lines
4.5 KiB
Nix
{ stdenv, fetchurl, substituteAll, libXrender, libXext
|
|
, libXfixes, freetype, fontconfig, zlib, libjpeg, libpng
|
|
, mesaSupported, mesa, mesa_glu, openssl, dbus, cups, pkgconfig
|
|
, libtiff, glib, icu, mysql, postgresql, sqlite, perl, coreutils, libXi
|
|
, gdk_pixbuf, python, gdb, xlibs, libX11, libxcb, xcbutil, xcbutilimage
|
|
, xcbutilkeysyms, xcbutilwm,udev, libxml2, libxslt, pcre, libxkbcommon
|
|
, alsaLib, gstreamer, gst_plugins_base
|
|
, pulseaudio, bison, flex, gperf, ruby, libwebp
|
|
, flashplayerFix ? false
|
|
, gtkStyle ? false, libgnomeui, gtk, GConf, gnome_vfs
|
|
, buildDocs ? false
|
|
, buildExamples ? false
|
|
, buildTests ? true
|
|
, developerBuild ? false
|
|
}:
|
|
|
|
with stdenv.lib;
|
|
|
|
let
|
|
v_maj = "5.1";
|
|
v_min = "1";
|
|
ver = "${v_maj}.${v_min}";
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "qt-${ver}";
|
|
|
|
src = fetchurl {
|
|
url = "http://download.qt-project.org/official_releases/qt/"
|
|
+ "${v_maj}/${ver}/single/qt-everywhere-opensource-src-${ver}.tar.gz";
|
|
sha256 = "4c05742db52325e96b1d610a2388140dcc1e3d03d93faea2b2d3791015b186f6";
|
|
};
|
|
|
|
# The version property must be kept because it will be included into the QtSDK package name
|
|
version = ver;
|
|
|
|
prePatch = ''
|
|
substituteInPlace configure --replace /bin/pwd pwd
|
|
substituteInPlace qtbase/configure --replace /bin/pwd pwd
|
|
substituteInPlace qtbase/src/corelib/global/global.pri --replace /bin/ls ${coreutils}/bin/ls
|
|
sed -e 's@/\(usr\|opt\)/@/var/empty/@g' -i config.tests/*/*.test -i qtbase/mkspecs/*/*.conf
|
|
'';
|
|
|
|
patches =
|
|
[ ./glib-2.32.patch
|
|
(substituteAll {
|
|
src = ./dlopen-absolute-paths.patch;
|
|
inherit cups icu libXfixes;
|
|
glibc = stdenv.gcc.libc;
|
|
openglDriver = if mesaSupported then mesa.driverLink else "/no-such-path";
|
|
})
|
|
] ++ optional gtkStyle (substituteAll {
|
|
src = ./dlopen-gtkstyle.patch;
|
|
# substituteAll ignores env vars starting with capital letter
|
|
gconf = GConf;
|
|
inherit gnome_vfs libgnomeui gtk;
|
|
})
|
|
++ optional flashplayerFix (substituteAll {
|
|
src = ./dlopen-webkit-nsplugin.patch;
|
|
inherit gtk gdk_pixbuf;
|
|
});
|
|
|
|
preConfigure = ''
|
|
export LD_LIBRARY_PATH="$PWD/qtbase/lib:$PWD/qtbase/plugins/platforms:$PWD/qttools/lib:$LD_LIBRARY_PATH"
|
|
export MAKEFLAGS=-j$NIX_BUILD_CORES
|
|
'';
|
|
|
|
prefixKey = "-prefix ";
|
|
|
|
# -no-eglfs, -no-directfb, -no-linuxfb and -no-kms because of the current minimalist mesa
|
|
# TODO Remove obsolete and useless flags once the build will be totally mastered
|
|
configureFlags = ''
|
|
-verbose
|
|
-confirm-license
|
|
-opensource
|
|
|
|
-release
|
|
-shared
|
|
-c++11
|
|
${optionalString developerBuild "-developer-build"}
|
|
-largefile
|
|
-accessibility
|
|
-rpath
|
|
-optimized-qmake
|
|
-strip
|
|
-reduce-relocations
|
|
-force-debug-info
|
|
-no-separate-debug-info
|
|
-system-proxies
|
|
|
|
-gui
|
|
-widgets
|
|
-opengl desktop
|
|
-javascript-jit
|
|
-qml-debug
|
|
-nis
|
|
-iconv
|
|
-icu
|
|
-pch
|
|
-glib
|
|
-xcb
|
|
-qpa xcb
|
|
-${optionalString (cups == null) "no-"}cups
|
|
|
|
-no-eglfs
|
|
-no-directfb
|
|
-no-linuxfb
|
|
-no-kms
|
|
|
|
-system-zlib
|
|
-system-libpng
|
|
-system-libjpeg
|
|
-system-xcb
|
|
-system-xkbcommon
|
|
-openssl-linked
|
|
-dbus-linked
|
|
|
|
-system-sqlite
|
|
-${if mysql != null then "plugin" else "no"}-sql-mysql
|
|
-${if postgresql != null then "plugin" else "no"}-sql-psql
|
|
|
|
-make libs
|
|
-make tools
|
|
-${optionalString (buildExamples == false) "no"}make examples
|
|
-${optionalString (buildTests == false) "no"}make tests
|
|
'';
|
|
|
|
propagatedBuildInputs = [
|
|
xlibs.libXcomposite libX11 libxcb libXext libXrender libXi
|
|
fontconfig freetype openssl dbus.libs glib udev libxml2 libxslt pcre
|
|
zlib libjpeg libpng libtiff sqlite icu
|
|
libwebp alsaLib gstreamer gst_plugins_base pulseaudio
|
|
xcbutil xcbutilimage xcbutilkeysyms xcbutilwm libxkbcommon
|
|
]
|
|
# Qt doesn't directly need GLU (just GL), but many apps use, it's small and
|
|
# doesn't remain a runtime-dep if not used
|
|
++ optionals mesaSupported [ mesa mesa_glu ]
|
|
++ optional (cups != null) cups
|
|
++ optional (mysql != null) mysql
|
|
++ optional (postgresql != null) postgresql;
|
|
|
|
buildInputs = [ gdb bison flex gperf ruby ];
|
|
|
|
nativeBuildInputs = [ python perl pkgconfig ];
|
|
|
|
postInstall = if buildDocs then "make docs&&make install_docs" else "";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
homepage = http://qt-project.org;
|
|
description = "A cross-platform application framework for C++";
|
|
license = "GPL/LGPL";
|
|
maintainers = [ maintainers.bbenoist ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|