2eacddf0dc
* pgadmin: use https homepage * msn-pecan: move homepage to github google code is now unavailable * pidgin-latex: use https for homepage * pidgin-opensteamworks: use github for homepage google code is unavailable * putty: use https for homepage * ponylang: use https for homepage * picolisp: use https for homepage * phonon: use https for homepage * pugixml: use https for homepage * pioneer: use https for homepage * packer: use https for homepage * pokerth: usee https for homepage * procps-ng: use https for homepage * pycaml: use https for homepage * proot: move homepage to .github.io * pius: use https for homepage * pdfread: use https for homepage * postgresql: use https for homepage * ponysay: move homepage to new site * prometheus: use https for homepage * powerdns: use https for homepage * pm-utils: use https for homepage * patchelf: move homepage to https * tesseract: move homepage to github * quodlibet: move homepage from google code * jbrout: move homepage from google code * eiskaltdcpp: move homepage to github * nodejs: use https to homepage * nix: use https for homepage * pdf2djvu: move homepage from google code * game-music-emu: move homepage from google code * vacuum: move homepae from google code
67 lines
1.9 KiB
Nix
67 lines
1.9 KiB
Nix
{ stdenv, lib, fetchurl, cmake, gst_all_1, phonon, pkgconfig
|
|
, extra-cmake-modules, qtbase ? null, qtx11extras ? null, qt4 ? null
|
|
, withQt5 ? false
|
|
, debug ? false
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let
|
|
v = "4.9.0";
|
|
pname = "phonon-backend-gstreamer";
|
|
in
|
|
|
|
assert withQt5 -> qtbase != null;
|
|
assert withQt5 -> qtx11extras != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "${pname}-${if withQt5 then "qt5" else "qt4"}-${v}";
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://phonon.kde.org/;
|
|
description = "GStreamer backend for Phonon";
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ ttuegel ];
|
|
};
|
|
|
|
src = fetchurl {
|
|
url = "mirror://kde/stable/phonon/${pname}/${v}/${pname}-${v}.tar.xz";
|
|
sha256 = "1wc5p1rqglf0n1avp55s50k7fjdzdrhg0gind15k8796w7nfbhyf";
|
|
};
|
|
|
|
# Hardcode paths to useful plugins so the backend doesn't depend
|
|
# on system paths being set.
|
|
patches = [ ./gst-plugin-paths.patch ];
|
|
|
|
NIX_CFLAGS_COMPILE =
|
|
let gstPluginPaths =
|
|
lib.makeSearchPathOutput "lib" "/lib/gstreamer-1.0"
|
|
(with gst_all_1; [
|
|
gstreamer
|
|
gst-plugins-base
|
|
gst-plugins-good
|
|
gst-plugins-ugly
|
|
gst-plugins-bad
|
|
gst-libav
|
|
]);
|
|
in [
|
|
# This flag should be picked up through pkgconfig, but it isn't.
|
|
"-I${gst_all_1.gstreamer.dev}/lib/gstreamer-1.0/include"
|
|
|
|
''-DGST_PLUGIN_PATH_1_0="${gstPluginPaths}"''
|
|
];
|
|
|
|
buildInputs = with gst_all_1;
|
|
[ gstreamer gst-plugins-base phonon ]
|
|
++ (if withQt5 then [ qtbase qtx11extras ] else [ qt4 ]);
|
|
|
|
# cleanup: the build system creates (empty) $out/$out/share/icons (double prefix)
|
|
# if DESTDIR is unset
|
|
DESTDIR="/";
|
|
|
|
nativeBuildInputs = [ cmake pkgconfig ] ++ optional withQt5 extra-cmake-modules;
|
|
|
|
cmakeFlags =
|
|
[ "-DCMAKE_BUILD_TYPE=${if debug then "Debug" else "Release"}" ]
|
|
++ optional withQt5 "-DPHONON_BUILD_PHONON4QT5=ON";
|
|
}
|