4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
49 lines
1.3 KiB
Nix
49 lines
1.3 KiB
Nix
{ lib, stdenv, fetchFromGitHub, bash, coreutils, gdb, zlib }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "procdump";
|
|
version = "1.1.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Microsoft";
|
|
repo = "ProcDump-for-Linux";
|
|
rev = version;
|
|
sha256 = "0h5fhk39d10kjbinzw1yp6nr8w8l300mn9qxrkpivdkyfn6bpq2f";
|
|
};
|
|
|
|
nativeBuildInputs = [ zlib ];
|
|
buildInputs = [ bash coreutils gdb ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace src/CoreDumpWriter.c \
|
|
--replace '"gcore ' '"${gdb}/bin/gcore ' \
|
|
--replace '"rm ' '"${coreutils}/bin/rm ' \
|
|
--replace '/bin/bash' '${bash}/bin/bash'
|
|
'';
|
|
|
|
makeFlags = [
|
|
"DESTDIR=${placeholder "out"}"
|
|
"INSTALLDIR=/bin"
|
|
"MANDIR=/share/man/man1"
|
|
];
|
|
|
|
doCheck = false; # needs sudo root
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
runHook preInstallCheck
|
|
set +o pipefail
|
|
($out/bin/procdump -h | grep "ProcDump v${version}") ||
|
|
(echo "ERROR: ProcDump is not the expected version or does not run properly" ; exit 1)
|
|
set -o pipefail
|
|
runHook postInstallCheck
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A Linux version of the ProcDump Sysinternals tool";
|
|
homepage = "https://github.com/Microsoft/ProcDump-for-Linux";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ c0bw3b ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|