fd78240ac8
At some point, I'd like to make another attempt at71f1f4884b("openssl: stop static binaries referencing libs"), which was reverted in195c7da07d. One problem with my previous attempt is that I moved OpenSSL's libraries to a lib output, but many dependent packages were hardcoding the out output as the location of the libraries. This patch fixes every such case I could find in the tree. It won't have any effect immediately, but will mean these packages will automatically use an OpenSSL lib output if it is reintroduced in future. This patch should cause very few rebuilds, because it shouldn't make any change at all to most packages I'm touching. The few rebuilds that are introduced come from when I've changed a package builder not to use variable names like openssl.out in scripts / substitution patterns, which would be confusing since they don't hardcode the output any more. I started by making the following global replacements: ${pkgs.openssl.out}/lib -> ${lib.getLib pkgs.openssl}/lib ${openssl.out}/lib -> ${lib.getLib openssl}/lib Then I removed the ".out" suffix when part of the argument to lib.makeLibraryPath, since that function uses lib.getLib internally. Then I fixed up cases where openssl was part of the -L flag to the compiler/linker, since that unambigously is referring to libraries. Then I manually investigated and fixed the following packages: - pycurl - citrix-workspace - ppp - wraith - unbound - gambit - acl2 I'm reasonably confindent in my fixes for all of them. For acl2, since the openssl library paths are manually provided above anyway, I don't think openssl is required separately as a build input at all. Removing it doesn't make a difference to the output size, the file list, or the closure. I've tested evaluation with the OfBorg meta checks, to protect against introducing evaluation failures.
75 lines
1.5 KiB
Nix
75 lines
1.5 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, substituteAll
|
|
, libpcap
|
|
, openssl
|
|
, bash
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "2.4.9";
|
|
pname = "ppp";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ppp-project";
|
|
repo = pname;
|
|
rev = "${pname}-${version}";
|
|
sha256 = "sha256-8+nbqRNfKPLDx+wmuKSkv+BSeG72hKJI4dNqypqeEK4=";
|
|
};
|
|
|
|
patches = [
|
|
(substituteAll {
|
|
src = ./nix-purity.patch;
|
|
glibc = stdenv.cc.libc.dev or stdenv.cc.libc;
|
|
openssl_dev = openssl.dev;
|
|
openssl_lib = lib.getLib openssl;
|
|
})
|
|
# Without nonpriv.patch, pppd --version doesn't work when not run as root.
|
|
./nonpriv.patch
|
|
];
|
|
|
|
buildInputs = [
|
|
libpcap
|
|
openssl
|
|
bash
|
|
];
|
|
|
|
postPatch = ''
|
|
for file in $(find -name Makefile.linux); do
|
|
substituteInPlace "$file" --replace '-m 4550' '-m 550'
|
|
done
|
|
|
|
patchShebangs --host \
|
|
scripts/{pon,poff,plog}
|
|
'';
|
|
|
|
makeFlags = [
|
|
"CC=${stdenv.cc.targetPrefix}cc"
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/bin
|
|
make install
|
|
install -D -m 755 scripts/{pon,poff,plog} $out/bin
|
|
runHook postInstall
|
|
'';
|
|
|
|
postFixup = ''
|
|
substituteInPlace "$out/bin/pon" --replace "/usr/sbin" "$out/bin"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://ppp.samba.org";
|
|
description = "Point-to-point implementation to provide Internet connections over serial lines";
|
|
license = with licenses; [
|
|
bsdOriginal
|
|
publicDomain
|
|
gpl2
|
|
lgpl2
|
|
];
|
|
platforms = platforms.linux;
|
|
maintainers = [ ];
|
|
};
|
|
}
|