4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
42 lines
1.4 KiB
Nix
42 lines
1.4 KiB
Nix
{ lib, stdenv, fetchurl, jre, makeWrapper, bash, coreutils, runtimeShell }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "zookeeper";
|
|
version = "3.6.2";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://apache/zookeeper/${pname}-${version}/apache-${pname}-${version}-bin.tar.gz";
|
|
sha512 = "caff5111bb6876b7124760bc006e6fa2523efa54b99321a3c9cd8192ea0d5596abc7d70a054b1aac9b20a411407dae7611c7aba870c23bff28eb1643ba499199";
|
|
};
|
|
|
|
buildInputs = [ makeWrapper jre ];
|
|
|
|
phases = ["unpackPhase" "installPhase"];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out
|
|
cp -R conf docs lib $out
|
|
# Without this, zkCli.sh tries creating a log file in the Nix store.
|
|
substituteInPlace $out/conf/log4j.properties \
|
|
--replace 'INFO, RFAAUDIT' 'INFO, CONSOLE'
|
|
mkdir -p $out/bin
|
|
cp -R bin/{zkCli,zkCleanup,zkEnv,zkServer,zkSnapShotToolkit,zkTxnLogToolkit}.sh $out/bin
|
|
patchShebangs $out/bin
|
|
substituteInPlace $out/bin/zkServer.sh \
|
|
--replace /bin/echo ${coreutils}/bin/echo
|
|
for i in $out/bin/{zkCli,zkCleanup,zkServer,zkSnapShotToolkit,zkTxnLogToolkit}.sh; do
|
|
wrapProgram $i \
|
|
--set JAVA_HOME "${jre}" \
|
|
--prefix PATH : "${bash}/bin"
|
|
done
|
|
chmod -x $out/bin/zkEnv.sh
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://zookeeper.apache.org";
|
|
description = "Apache Zookeeper";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ nathan-gs cstrahan pradeepchhetri ztzg ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|