4176d58331
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/packagekit/versions. These checks were done: - built on NixOS - ran ‘/nix/store/lxwq08kfybd0zlg06xk0zj606nlpk3bn-packagekit-1.1.10/bin/pkcon -h’ got 0 exit code - ran ‘/nix/store/lxwq08kfybd0zlg06xk0zj606nlpk3bn-packagekit-1.1.10/bin/pkcon --help’ got 0 exit code - ran ‘/nix/store/lxwq08kfybd0zlg06xk0zj606nlpk3bn-packagekit-1.1.10/bin/pkmon -h’ got 0 exit code - ran ‘/nix/store/lxwq08kfybd0zlg06xk0zj606nlpk3bn-packagekit-1.1.10/bin/pkmon --help’ got 0 exit code - found 1.1.10 with grep in /nix/store/lxwq08kfybd0zlg06xk0zj606nlpk3bn-packagekit-1.1.10 - directory tree listing: https://gist.github.com/1d641323594032d2e935bd1e088bf409
69 lines
2.4 KiB
Nix
69 lines
2.4 KiB
Nix
{ stdenv, fetchFromGitHub, lib
|
|
, intltool, glib, pkgconfig, polkit, python, sqlite, systemd
|
|
, gobjectIntrospection, vala_0_38, gtk-doc, autoreconfHook, autoconf-archive
|
|
# TODO: set enableNixBackend to true, as soon as it builds
|
|
, nix, enableNixBackend ? false, boost
|
|
, enableCommandNotFound ? false
|
|
, enableBashCompletion ? false, bash-completion ? null }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "packagekit-${version}";
|
|
version = "1.1.10";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "hughsie";
|
|
repo = "PackageKit";
|
|
rev = "PACKAGEKIT_${lib.replaceStrings ["."] ["_"] version}";
|
|
sha256 = "11drd6ixx75q3w12am3z1npwllq1kxnhbxv0npng92c69kn291zs";
|
|
};
|
|
|
|
buildInputs = [ glib polkit systemd python gobjectIntrospection vala_0_38 ]
|
|
++ lib.optional enableBashCompletion bash-completion;
|
|
propagatedBuildInputs = [ sqlite nix boost ];
|
|
nativeBuildInputs = [ intltool pkgconfig autoreconfHook autoconf-archive gtk-doc ];
|
|
|
|
preAutoreconf = ''
|
|
gtkdocize
|
|
intltoolize
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--enable-systemd"
|
|
"--disable-dummy"
|
|
"--disable-cron"
|
|
"--disable-introspection"
|
|
"--disable-offline-update"
|
|
"--localstatedir=/var"
|
|
"--sysconfdir=/etc"
|
|
"--with-dbus-sys=$(out)/etc/dbus-1/system.d"
|
|
"--with-systemdsystemunitdir=$(out)/lib/systemd/system/"
|
|
]
|
|
++ lib.optional enableNixBackend "--enable-nix"
|
|
++ lib.optional (!enableBashCompletion) "--disable-bash-completion"
|
|
++ lib.optional (!enableCommandNotFound) "--disable-command-not-found";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
installFlags = [
|
|
"sysconfdir=\${out}/etc"
|
|
"localstatedir=\${TMPDIR}"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "System to facilitate installing and updating packages";
|
|
longDescription = ''
|
|
PackageKit is a system designed to make installing and updating software
|
|
on your computer easier. The primary design goal is to unify all the
|
|
software graphical tools used in different distributions, and use some of
|
|
the latest technology like PolicyKit. The actual nuts-and-bolts distro
|
|
tool (dnf, apt, etc) is used by PackageKit using compiled and scripted
|
|
helpers. PackageKit isn't meant to replace these tools, instead providing
|
|
a common set of abstractions that can be used by standard GUI and text
|
|
mode package managers.
|
|
'';
|
|
homepage = http://www.packagekit.org/;
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ matthewbauer ];
|
|
};
|
|
}
|