4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ lib, stdenv, fetchurl, pythonPackages, installShellFiles }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "2.4.1";
|
|
pname = "weather";
|
|
|
|
src = fetchurl {
|
|
url = "http://fungi.yuggoth.org/weather/src/${pname}-${version}.tar.xz";
|
|
sha256 = "0nf680dl7a2vlgavdhj6ljq8a7lkhvr6zghkpzad53vmilxsndys";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
pythonPackages.wrapPython
|
|
];
|
|
|
|
dontConfigure = true;
|
|
dontBuild = true;
|
|
|
|
# Upstream doesn't provide a setup.py or alike, so we follow:
|
|
# http://fungi.yuggoth.org/weather/doc/install.rst#id3
|
|
installPhase = ''
|
|
site_packages=$out/${pythonPackages.python.sitePackages}
|
|
install -Dt $out/bin -m 755 weather
|
|
install -Dt $site_packages weather.py
|
|
install -Dt $out/share/weather-util \
|
|
airports overrides.{conf,log} places slist stations \
|
|
zctas zlist zones
|
|
install -Dt $out/etc weatherrc
|
|
|
|
sed -i \
|
|
-e "s|/etc|$out/etc|g" \
|
|
-e "s|else: default_setpath = \".:~/.weather|&:$out/share/weather-util|" \
|
|
$site_packages/weather.py
|
|
|
|
wrapPythonPrograms
|
|
|
|
installManPage weather.1 weatherrc.5
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "http://fungi.yuggoth.org/weather";
|
|
description = "Quick access to current weather conditions and forecasts";
|
|
license = licenses.isc;
|
|
maintainers = [ maintainers.matthiasbeyer ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|