215a07c1a9
Merge conflicts: * unzip (almost trivial) * dvswitch (trivial) * gmp (copied result of `git merge`) The last item introduced gmp-5.0.3, thus full rebuild. +ensureDir->mkdir -p in TeX packages was catched by git but not svn. svn path=/nixpkgs/branches/stdenv-updates/; revision=32091
57 lines
1.6 KiB
Nix
57 lines
1.6 KiB
Nix
{ fetchurl, stdenv, replace, curl, expat, zlib, bzip2, libarchive
|
|
, useNcurses ? false, ncurses, useQt4 ? false, qt4
|
|
, darwinInstallNameToolUtility }:
|
|
|
|
with stdenv.lib;
|
|
|
|
let
|
|
os = stdenv.lib.optionalString;
|
|
majorVersion = "2.8";
|
|
minorVersion = "7";
|
|
version = "${majorVersion}.${minorVersion}";
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "cmake-${os useNcurses "cursesUI-"}${os useQt4 "qt4UI-"}${version}";
|
|
|
|
inherit majorVersion;
|
|
|
|
src = fetchurl {
|
|
url = "${meta.homepage}files/v${majorVersion}/cmake-${version}.tar.gz";
|
|
sha256 = "17zmxh0gyis6w05d2km0swlvy94h3w10jgra0fpa5qcg7l2j628k";
|
|
};
|
|
|
|
patches =
|
|
# Don't search in non-Nix locations such as /usr, but do search in
|
|
# Nixpkgs' Glibc.
|
|
optional (stdenv ? glibc) ./search-path.patch;
|
|
|
|
buildInputs = [ curl expat zlib bzip2 libarchive ]
|
|
++ optional stdenv.isDarwin darwinInstallNameToolUtility
|
|
++ optional useNcurses ncurses
|
|
++ optional useQt4 qt4;
|
|
|
|
CMAKE_PREFIX_PATH = stdenv.lib.concatStringsSep ":" buildInputs;
|
|
|
|
configureFlags =
|
|
"--docdir=/share/doc/${name} --mandir=/share/man --system-libs"
|
|
+ stdenv.lib.optionalString useQt4 " --qt-gui";
|
|
|
|
setupHook = ./setup-hook.sh;
|
|
|
|
dontUseCmakeConfigure = true;
|
|
|
|
preConfigure = optionalString (stdenv ? glibc)
|
|
''
|
|
source $setupHook
|
|
fixCmakeFiles .
|
|
substituteInPlace Modules/Platform/UnixPaths.cmake --subst-var-by glibc ${stdenv.glibc}
|
|
'';
|
|
|
|
meta = {
|
|
homepage = http://www.cmake.org/;
|
|
description = "Cross-Platform Makefile Generator";
|
|
platforms = if useQt4 then qt4.meta.platforms else stdenv.lib.platforms.all;
|
|
maintainers = [ stdenv.lib.maintainers.urkud ];
|
|
};
|
|
}
|