fd78240ac8
At some point, I'd like to make another attempt at71f1f4884b("openssl: stop static binaries referencing libs"), which was reverted in195c7da07d. One problem with my previous attempt is that I moved OpenSSL's libraries to a lib output, but many dependent packages were hardcoding the out output as the location of the libraries. This patch fixes every such case I could find in the tree. It won't have any effect immediately, but will mean these packages will automatically use an OpenSSL lib output if it is reintroduced in future. This patch should cause very few rebuilds, because it shouldn't make any change at all to most packages I'm touching. The few rebuilds that are introduced come from when I've changed a package builder not to use variable names like openssl.out in scripts / substitution patterns, which would be confusing since they don't hardcode the output any more. I started by making the following global replacements: ${pkgs.openssl.out}/lib -> ${lib.getLib pkgs.openssl}/lib ${openssl.out}/lib -> ${lib.getLib openssl}/lib Then I removed the ".out" suffix when part of the argument to lib.makeLibraryPath, since that function uses lib.getLib internally. Then I fixed up cases where openssl was part of the -L flag to the compiler/linker, since that unambigously is referring to libraries. Then I manually investigated and fixed the following packages: - pycurl - citrix-workspace - ppp - wraith - unbound - gambit - acl2 I'm reasonably confindent in my fixes for all of them. For acl2, since the openssl library paths are manually provided above anyway, I don't think openssl is required separately as a build input at all. Removing it doesn't make a difference to the output size, the file list, or the closure. I've tested evaluation with the OfBorg meta checks, to protect against introducing evaluation failures.
96 lines
2.3 KiB
Nix
96 lines
2.3 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchurl
|
|
, autoPatchelfHook
|
|
, dpkg
|
|
, gtk2
|
|
, openssl
|
|
, pcsclite
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "pcsc-safenet";
|
|
version = "10.0.37-0";
|
|
|
|
# https://aur.archlinux.org/packages/sac-core/
|
|
src = fetchurl {
|
|
url = "https://storage.spidlas.cz/public/soft/safenet/SafenetAuthenticationClient-core-${version}_amd64.deb";
|
|
sha256 = "1r9739bhal7ramj1rpawaqvik45xbs1c756l1da96din638gzy5l";
|
|
};
|
|
|
|
dontBuild = true;
|
|
dontConfigure = true;
|
|
|
|
unpackPhase = ''
|
|
dpkg-deb -x $src .
|
|
'';
|
|
|
|
buildInputs = [
|
|
gtk2
|
|
openssl
|
|
pcsclite
|
|
];
|
|
|
|
runtimeDependencies = [
|
|
openssl
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
autoPatchelfHook
|
|
dpkg
|
|
];
|
|
|
|
installPhase = ''
|
|
# Set up for pcsc drivers
|
|
mkdir -p pcsc/drivers
|
|
mv usr/share/eToken/drivers/* pcsc/drivers/
|
|
rm -r usr/share/eToken/drivers
|
|
|
|
# Move binaries out
|
|
mv usr/bin bin
|
|
|
|
# Move UI to bin
|
|
mv usr/share/SAC/SACUIProcess bin/
|
|
rm -r usr/share/SAC
|
|
|
|
mkdir $out
|
|
cp -r {bin,etc,lib,pcsc,usr,var} $out/
|
|
|
|
cd "$out/lib/"
|
|
ln -sf libeToken.so.10.0.37 libeTPkcs11.so
|
|
ln -sf libeToken.so.10.0.37 libeToken.so.10.0
|
|
ln -sf libeToken.so.10.0.37 libeToken.so.10
|
|
ln -sf libeToken.so.10.0.37 libeToken.so
|
|
ln -sf libcardosTokenEngine.so.10.0.37 libcardosTokenEngine.so.10.0
|
|
ln -sf libcardosTokenEngine.so.10.0.37 libcardosTokenEngine.so.10
|
|
ln -sf libcardosTokenEngine.so.10.0.37 libcardosTokenEngine.so
|
|
|
|
cd $out/pcsc/drivers/aks-ifdh.bundle/Contents/Linux/
|
|
ln -sf libAksIfdh.so.10.0 libAksIfdh.so
|
|
ln -sf libAksIfdh.so.10.0 libAksIfdh.so.10
|
|
|
|
ln -sf ${lib.getLib openssl}/lib/libcrypto.so $out/lib/libcrypto.so.1.0.0
|
|
'';
|
|
|
|
dontAutoPatchelf = true;
|
|
|
|
# Patch DYN shared libraries (autoPatchElfHook only patches EXEC | INTERP).
|
|
postFixup = ''
|
|
autoPatchelf "$out"
|
|
|
|
runtime_rpath="${lib.makeLibraryPath runtimeDependencies}"
|
|
|
|
for mod in $(find "$out" -type f -name '*.so.*'); do
|
|
mod_rpath="$(patchelf --print-rpath "$mod")"
|
|
patchelf --set-rpath "$runtime_rpath:$mod_rpath" "$mod"
|
|
done;
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://safenet.gemalto.com/multi-factor-authentication/security-applications/authentication-client-token-management";
|
|
description = "Safenet Authentication Client";
|
|
platforms = [ "x86_64-linux" ];
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ wldhx ];
|
|
};
|
|
}
|