fd78240ac8
At some point, I'd like to make another attempt at71f1f4884b("openssl: stop static binaries referencing libs"), which was reverted in195c7da07d. One problem with my previous attempt is that I moved OpenSSL's libraries to a lib output, but many dependent packages were hardcoding the out output as the location of the libraries. This patch fixes every such case I could find in the tree. It won't have any effect immediately, but will mean these packages will automatically use an OpenSSL lib output if it is reintroduced in future. This patch should cause very few rebuilds, because it shouldn't make any change at all to most packages I'm touching. The few rebuilds that are introduced come from when I've changed a package builder not to use variable names like openssl.out in scripts / substitution patterns, which would be confusing since they don't hardcode the output any more. I started by making the following global replacements: ${pkgs.openssl.out}/lib -> ${lib.getLib pkgs.openssl}/lib ${openssl.out}/lib -> ${lib.getLib openssl}/lib Then I removed the ".out" suffix when part of the argument to lib.makeLibraryPath, since that function uses lib.getLib internally. Then I fixed up cases where openssl was part of the -L flag to the compiler/linker, since that unambigously is referring to libraries. Then I manually investigated and fixed the following packages: - pycurl - citrix-workspace - ppp - wraith - unbound - gambit - acl2 I'm reasonably confindent in my fixes for all of them. For acl2, since the openssl library paths are manually provided above anyway, I don't think openssl is required separately as a build input at all. Removing it doesn't make a difference to the output size, the file list, or the closure. I've tested evaluation with the OfBorg meta checks, to protect against introducing evaluation failures.
69 lines
1.9 KiB
Nix
69 lines
1.9 KiB
Nix
{ lib, stdenv, fetchurl, gnutls, openssl, libgcrypt, libgpg-error, pkg-config, gettext
|
|
, which
|
|
|
|
# GUI support
|
|
, gtk2, gtk3, qt5
|
|
|
|
, pluginSearchPaths ? [
|
|
"/run/current-system/sw/lib/gwenhywfar/plugins"
|
|
".nix-profile/lib/gwenhywfar/plugins"
|
|
]
|
|
}:
|
|
|
|
let
|
|
inherit ((import ./sources.nix).gwenhywfar) sha256 releaseId version;
|
|
in stdenv.mkDerivation rec {
|
|
pname = "gwenhywfar";
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url = "https://www.aquamaniac.de/rdm/attachments/download/${releaseId}/${pname}-${version}.tar.gz";
|
|
inherit sha256;
|
|
};
|
|
|
|
configureFlags = [
|
|
"--with-openssl-includes=${openssl.dev}/include"
|
|
"--with-openssl-libs=${lib.getLib openssl}/lib"
|
|
];
|
|
|
|
preConfigure = ''
|
|
configureFlagsArray+=("--with-guis=gtk2 gtk3 qt5")
|
|
'';
|
|
|
|
postPatch = let
|
|
isRelative = path: builtins.substring 0 1 path != "/";
|
|
mkSearchPath = path: ''
|
|
p; g; s,\<PLUGINDIR\>,"${path}",g;
|
|
'' + lib.optionalString (isRelative path) ''
|
|
s/AddPath(\(.*\));/AddRelPath(\1, GWEN_PathManager_RelModeHome);/g
|
|
'';
|
|
|
|
in ''
|
|
sed -i -e '/GWEN_PathManager_DefinePath.*GWEN_PM_PLUGINDIR/,/^#endif/ {
|
|
/^#if/,/^#endif/ {
|
|
H; /^#endif/ {
|
|
${lib.concatMapStrings mkSearchPath pluginSearchPaths}
|
|
}
|
|
}
|
|
}' src/gwenhywfar.c
|
|
|
|
# Strip off the effective SO version from the path so that for example
|
|
# "lib/gwenhywfar/plugins/60" becomes just "lib/gwenhywfar/plugins".
|
|
sed -i -e '/^gwenhywfar_plugindir=/s,/\''${GWENHYWFAR_SO_EFFECTIVE},,' \
|
|
configure
|
|
'';
|
|
|
|
nativeBuildInputs = [ pkg-config gettext which ];
|
|
|
|
buildInputs = [ gtk2 gtk3 qt5.qtbase gnutls openssl libgcrypt libgpg-error ];
|
|
|
|
dontWrapQtApps = true;
|
|
|
|
meta = with lib; {
|
|
description = "OS abstraction functions used by aqbanking and related tools";
|
|
homepage = "https://www.aquamaniac.de/rdm/projects/gwenhywfar";
|
|
license = licenses.lgpl21Plus;
|
|
maintainers = with maintainers; [ goibhniu ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|