79 lines
2 KiB
Nix
79 lines
2 KiB
Nix
{ lib
|
|
, stdenv
|
|
, rustPlatform
|
|
, fetchCrate
|
|
, pinentry
|
|
, openssl
|
|
, pkg-config
|
|
, makeWrapper
|
|
, Security
|
|
|
|
# rbw-fzf
|
|
, withFzf ? false, fzf, perl
|
|
|
|
# rbw-rofi
|
|
, withRofi ? false, rofi, xclip
|
|
|
|
# pass-import
|
|
, withPass ? false, pass
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "rbw";
|
|
version = "1.0.0"; # do not upgrate 1.1.0 yet, because it doesn't build on Darwin
|
|
|
|
src = fetchCrate {
|
|
inherit version;
|
|
crateName = pname;
|
|
sha256 = "0yqn65izcwbh7g085hwq4wrg9y9jlz1xbrq69b6ypqxi9abqnp6q";
|
|
};
|
|
|
|
cargoSha256 = "0x00clixdbpqif2wzhj3f4k9kpza623xs8a05wq4g15227kz7mlm";
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
makeWrapper
|
|
];
|
|
|
|
buildInputs = lib.optionals stdenv.isDarwin [ Security ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace src/pinentry.rs \
|
|
--replace 'Command::new("pinentry")' 'Command::new("${pinentry}/${pinentry.binaryPath or "bin/pinentry"}")'
|
|
'' + lib.optionalString withFzf ''
|
|
patchShebangs bin/rbw-fzf
|
|
substituteInPlace bin/rbw-fzf \
|
|
--replace fzf ${fzf}/bin/fzf \
|
|
--replace perl ${perl}/bin/perl
|
|
'' + lib.optionalString withRofi ''
|
|
patchShebangs bin/rbw-rofi
|
|
substituteInPlace bin/rbw-rofi \
|
|
--replace rofi ${rofi}/bin/rofi \
|
|
--replace xclip ${xclip}/bin/xclip
|
|
'' + lib.optionalString withRofi ''
|
|
patchShebangs bin/pass-import
|
|
substituteInPlace bin/pass-import \
|
|
--replace pass ${pass}/bin/pass
|
|
'';
|
|
|
|
preConfigure = ''
|
|
export OPENSSL_INCLUDE_DIR="${openssl.dev}/include"
|
|
export OPENSSL_LIB_DIR="${openssl.out}/lib"
|
|
'';
|
|
|
|
postInstall = lib.optionalString withFzf ''
|
|
cp bin/rbw-fzf $out/bin
|
|
'' + lib.optionalString withRofi ''
|
|
cp bin/rbw-rofi $out/bin
|
|
'' + lib.optionalString withPass ''
|
|
cp bin/pass-import $out/bin
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Unofficial command line client for Bitwarden";
|
|
homepage = "https://crates.io/crates/rbw";
|
|
changelog = "https://git.tozt.net/rbw/plain/CHANGELOG.md?id=${version}";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ albakham luc65r marsam ];
|
|
};
|
|
}
|