c3c4ef859a
GPRbuild is a multi language build system developed by AdaCore which is mostly used for build Ada-related projects using GNAT. Since GPRbuild is used to build itself and its dependency library XML/Ada we first build a bootstrap version of it using the provided bash build script bootstrap.sh as the gprbuild-boot derivation. gprbuild-boot is then used to build xmlada and the proper gprbuild derivation. GPRbuild has its own search path mechanism via GPR_PROJECT_PATH which we address via a setupHook. It currently works quite similar to the pkg-config one: It accumulates all inputs into GPR_PROJECT_PATH, GPR_PROJECT_PATH_FOR_BUILD etc. However this is quite limited at the moment as we don't have a gprbuild wrapper yet which understands the _FOR_BUILD suffix. However, we'll need to address this in the future as it is currently basically impossible to test since the distinction only affects cross-compilation, but it is not possible to build a GNAT cross-compiler in nixpkgs at the moment (I'm working on changing that, however). Another issue we had to solve was GPRbuild not finding the right GNAT via its gprconfig tool: GPRbuild has a knowledge base with compiler definitions which run some checks and collect info about binaries which are in PATH. In the end the first compiler in PATH that supports the desired language is selected. We want GPRbuild to discover our wrapped GNAT since the unwrapped one is incapable of producing working binaries since it won't find the crt*.o objects distributed with libc. GPRbuild however needs to find the Ada runtime distributed with GNAT which is not part of the wrapper derivation, so it will skip the wrapper and select the unwrapped GNAT. Symlinking the unwrapped's lib directory into the wrapper fixes this problem, but breaks linking in some cases (e. g. when linking against OMP from gcc, the runtime variant will shadow the problem dynamic lib from buildInputs). Additionally it uses gnatls as an indicator it has found GNAT which is not part of the wrapper. The solution we opted to adopt here is to install a custom compiler description into gprbuild's knowledge base which properly detects the nixpkgs GNAT wrapper: It uses gnatmake to detect GNAT instead of gnatls and discovers the runtime via a symlink we add to `$out/nix-support`. This additional definition is enough to properly detect GNAT, since the plain wrapped gcc detection works out of the box. It may, however, be necessary to add special definitions for other languages in the future where gprbuild also needs to discover the runtime. One future improvement would be to install libgpr into a separate output or split it into a separate derivation (which would require to link gprbuild statically always since otherwise we end up with a cyclical dependency).
90 lines
2.6 KiB
Nix
90 lines
2.6 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromGitHub
|
|
, gnat
|
|
, which
|
|
, xmlada # for src
|
|
}:
|
|
|
|
let
|
|
version = "21.0.0";
|
|
|
|
gprConfigKbSrc = fetchFromGitHub {
|
|
name = "gprconfig-kb-${version}-src";
|
|
owner = "AdaCore";
|
|
repo = "gprconfig_kb";
|
|
rev = "v${version}";
|
|
sha256 = "11qmzfdd0ipmhxl4k2hjidqc9i40bywrfkbiivd3lhscxca5pxpg";
|
|
};
|
|
in
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "gprbuild-boot";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
name = "gprbuild-${version}";
|
|
owner = "AdaCore";
|
|
repo = "gprbuild";
|
|
rev = "v${version}";
|
|
sha256 = "1knpwasbrz6sxh3dhkc4izchcz4km04j77r4vxxhi23fbd8v1ynj";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
gnat
|
|
which
|
|
];
|
|
|
|
postPatch = ''
|
|
# The Makefile uses gprbuild to build gprbuild which
|
|
# we can't do at this point, delete it to prevent the
|
|
# default phases from failing.
|
|
rm Makefile
|
|
|
|
# make sure bootstrap script runs
|
|
patchShebangs --build bootstrap.sh
|
|
'';
|
|
|
|
# This setupHook populates GPR_PROJECT_PATH which is used by
|
|
# gprbuild to find dependencies. It works quite similar to
|
|
# the pkg-config setupHook in the sense that it also splits
|
|
# dependencies into GPR_PROJECT_PATH and GPR_PROJECT_PATH_FOR_BUILD,
|
|
# but gprbuild itself doesn't support this, so we'll need to
|
|
# introducing a wrapper for it in the future remains TODO.
|
|
# For the moment this doesn't matter since we have no situation
|
|
# were gprbuild is used to build something used at build time.
|
|
setupHook = ./gpr-project-path-hook.sh;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
./bootstrap.sh \
|
|
--with-xmlada=${xmlada.src} \
|
|
--with-kb=${gprConfigKbSrc} \
|
|
--prefix=$out
|
|
|
|
# Install custom compiler description which can detect nixpkgs'
|
|
# GNAT wrapper as a proper Ada compiler. The default compiler
|
|
# description expects the runtime library to be installed in
|
|
# the same prefix which isn't the case for nixpkgs. As a
|
|
# result, it would detect the unwrapped GNAT as a proper
|
|
# compiler which is unable to produce working binaries.
|
|
#
|
|
# Our compiler description is very similar to the upstream
|
|
# GNAT description except that we use a symlink in $out/nix-support
|
|
# created by the cc-wrapper to find the associated runtime
|
|
# libraries and use gnatmake instead of gnatls to find GNAT's
|
|
# bin directory.
|
|
install -m644 ${./nixpkgs-gnat.xml} $out/share/gprconfig/nixpkgs-gnat.xml
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Multi-language extensible build tool";
|
|
homepage = "https://github.com/AdaCore/gprbuild";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = [ maintainers.sternenseemann ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|