4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
74 lines
1.9 KiB
Nix
74 lines
1.9 KiB
Nix
{ lib, stdenv, fetchurl, buildPackages }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "tzdata";
|
|
version = "2020f";
|
|
|
|
srcs =
|
|
[ (fetchurl {
|
|
url = "https://data.iana.org/time-zones/releases/tzdata${version}.tar.gz";
|
|
sha256 = "10b8cr55x6ji14n3kqkn3avj1s9b79b8gszh81fxrrisij8k248j";
|
|
})
|
|
(fetchurl {
|
|
url = "https://data.iana.org/time-zones/releases/tzcode${version}.tar.gz";
|
|
sha256 = "1i998crd9fxdfhv4jd241j1arx0ng7j7cvczpmj4y5j5fwmfmvng";
|
|
})
|
|
];
|
|
|
|
sourceRoot = ".";
|
|
|
|
outputs = [ "out" "bin" "man" "dev" ];
|
|
propagatedBuildOutputs = [];
|
|
|
|
makeFlags = [
|
|
"TOPDIR=$(out)"
|
|
"TZDIR=$(out)/share/zoneinfo"
|
|
"BINDIR=$(bin)/bin"
|
|
"ZICDIR=$(bin)/bin"
|
|
"ETCDIR=$(TMPDIR)/etc"
|
|
"TZDEFAULT=$(TMPDIR)/etc"
|
|
"LIBDIR=$(dev)/lib"
|
|
"MANDIR=$(man)/share/man"
|
|
"AWK=awk"
|
|
"CFLAGS=-DHAVE_LINK=0"
|
|
"CFLAGS+=-DZIC_BLOAT_DEFAULT=\\\"fat\\\""
|
|
"cc=${stdenv.cc.targetPrefix}cc"
|
|
"AR=${stdenv.cc.targetPrefix}ar"
|
|
];
|
|
|
|
depsBuildBuild = [ buildPackages.stdenv.cc ];
|
|
|
|
doCheck = false; # needs more tools
|
|
|
|
installFlags = [ "ZIC=./zic-native" ];
|
|
|
|
preInstall = ''
|
|
mv zic.o zic.o.orig
|
|
mv zic zic.orig
|
|
make $makeFlags cc=cc AR=ar zic
|
|
mv zic zic-native
|
|
mv zic.o.orig zic.o
|
|
mv zic.orig zic
|
|
'';
|
|
|
|
postInstall =
|
|
''
|
|
rm $out/share/zoneinfo-posix
|
|
mkdir $out/share/zoneinfo/posix
|
|
( cd $out/share/zoneinfo/posix; ln -s ../* .; rm posix )
|
|
mv $out/share/zoneinfo-leaps $out/share/zoneinfo/right
|
|
|
|
mkdir -p "$dev/include"
|
|
cp tzfile.h "$dev/include/tzfile.h"
|
|
'';
|
|
|
|
setupHook = ./tzdata-setup-hook.sh;
|
|
|
|
meta = with lib; {
|
|
homepage = "http://www.iana.org/time-zones";
|
|
description = "Database of current and historical time zones";
|
|
changelog = "https://github.com/eggert/tz/blob/${version}/NEWS";
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ fpletz ];
|
|
};
|
|
}
|