af38b888fc
Semi-automatic update. These checks were performed: - built on NixOS - ran `/nix/store/cqjd4b5av6rrmmz9qvagqgq2vqwi5mmi-qgis-2.18.16/bin/qgis_bench -h` got 0 exit code - found 2.18.16 with grep in /nix/store/cqjd4b5av6rrmmz9qvagqgq2vqwi5mmi-qgis-2.18.16 cc "@viric"
47 lines
1.9 KiB
Nix
47 lines
1.9 KiB
Nix
{ stdenv, fetchurl, fetchpatch, gdal, cmake, qt4, flex, bison, proj, geos, xlibsWrapper, sqlite, gsl
|
|
, qwt, fcgi, python2Packages, libspatialindex, libspatialite, qscintilla, postgresql, makeWrapper
|
|
, qjson, qca2, txt2tags, openssl
|
|
, withGrass ? false, grass
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "qgis-2.18.16";
|
|
|
|
buildInputs = [ gdal qt4 flex openssl bison proj geos xlibsWrapper sqlite gsl qwt qscintilla
|
|
fcgi libspatialindex libspatialite postgresql qjson qca2 txt2tags ] ++
|
|
(stdenv.lib.optional withGrass grass) ++
|
|
(with python2Packages; [ jinja2 numpy psycopg2 pygments requests python2Packages.qscintilla sip ]);
|
|
|
|
nativeBuildInputs = [ cmake makeWrapper ];
|
|
|
|
# `make -f src/providers/wms/CMakeFiles/wmsprovider_a.dir/build.make src/providers/wms/CMakeFiles/wmsprovider_a.dir/qgswmssourceselect.cpp.o`:
|
|
# fatal error: ui_qgsdelimitedtextsourceselectbase.h: No such file or directory
|
|
enableParallelBuilding = false;
|
|
|
|
# To handle the lack of 'local' RPATH; required, as they call one of
|
|
# their built binaries requiring their libs, in the build process.
|
|
preBuild = ''
|
|
export LD_LIBRARY_PATH=`pwd`/output/lib:${stdenv.lib.makeLibraryPath [ openssl ]}:$LD_LIBRARY_PATH
|
|
'';
|
|
|
|
src = fetchurl {
|
|
url = "http://qgis.org/downloads/${name}.tar.bz2";
|
|
sha256 = "0d880m013kzi4qiyr27yjx6hzpb652slp66gyqgw9ziw03wy12c9";
|
|
};
|
|
|
|
cmakeFlags = stdenv.lib.optional withGrass "-DGRASS_PREFIX7=${grass}/${grass.name}";
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/qgis \
|
|
--prefix PYTHONPATH : $PYTHONPATH \
|
|
--prefix LD_LIBRARY_PATH : ${stdenv.lib.makeLibraryPath [ openssl ]}
|
|
'';
|
|
|
|
meta = {
|
|
description = "User friendly Open Source Geographic Information System";
|
|
homepage = http://www.qgis.org;
|
|
license = stdenv.lib.licenses.gpl2Plus;
|
|
platforms = with stdenv.lib.platforms; linux;
|
|
maintainers = with stdenv.lib.maintainers; [viric];
|
|
};
|
|
}
|