48459567ae
Closes #216989 First of all, a bit of context: in PostgreSQL, newly created users don't have the CREATE privilege on the public schema of a database even with `ALL PRIVILEGES` granted via `ensurePermissions` which is how most of the DB users are currently set up "declaratively"[1]. This means e.g. a freshly deployed Nextcloud service will break early because Nextcloud itself cannot CREATE any tables in the public schema anymore. The other issue here is that `ensurePermissions` is a mere hack. It's effectively a mixture of SQL code (e.g. `DATABASE foo` is relying on how a value is substituted in a query. You'd have to parse a subset of SQL to actually know which object are permissions granted to for a user). After analyzing the existing modules I realized that in every case with a single exception[2] the UNIX system user is equal to the db user is equal to the db name and I don't see a compelling reason why people would change that in 99% of the cases. In fact, some modules would even break if you'd change that because the declarations of the system user & the db user are mixed up[3]. So I decided to go with something new which restricts the ways to use `ensure*` options rather than expanding those[4]. Effectively this means that * The DB user _must_ be equal to the DB name. * Permissions are granted via `ensureDBOwnerhip` for an attribute-set in `ensureUsers`. That way, the user is actually the owner and can perform `CREATE`. * For such a postgres user, a database must be declared in `ensureDatabases`. For anything else, a custom state management should be implemented. This can either be `initialScript`, doing it manual, outside of the module or by implementing proper state management for postgresql[5], but the current state of `ensure*` isn't even declarative, but a convergent tool which is what Nix actually claims to _not_ do. Regarding existing setups: there are effectively two options: * Leave everything as-is (assuming that system user == db user == db name): then the DB user will automatically become the DB owner and everything else stays the same. * Drop the `createDatabase = true;` declarations: nothing will change because a removal of `ensure*` statements is ignored, so it doesn't matter at all whether this option is kept after the first deploy (and later on you'd usually restore from backups anyways). The DB user isn't the owner of the DB then, but for an existing setup this is irrelevant because CREATE on the public schema isn't revoked from existing users (only not granted for new users). [1] not really declarative though because removals of these statements are simply ignored for instance: https://github.com/NixOS/nixpkgs/issues/206467 [2] `services.invidious`: I removed the `ensure*` part temporarily because it IMHO falls into the category "manage the state on your own" (see the commit message). See also https://github.com/NixOS/nixpkgs/pull/265857 [3] e.g. roundcube had `"DATABASE ${cfg.database.username}" = "ALL PRIVILEGES";` [4] As opposed to other changes that are considered a potential fix, but also add more things like collation for DBs or passwords that are _never_ touched again when changing those. [5] As suggested in e.g. https://github.com/NixOS/nixpkgs/issues/206467
106 lines
3.4 KiB
Nix
106 lines
3.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
cfg = config.services.hockeypuck;
|
|
settingsFormat = pkgs.formats.toml { };
|
|
in {
|
|
meta.maintainers = with lib.maintainers; [ etu ];
|
|
|
|
options.services.hockeypuck = {
|
|
enable = lib.mkEnableOption (lib.mdDoc "Hockeypuck OpenPGP Key Server");
|
|
|
|
port = lib.mkOption {
|
|
default = 11371;
|
|
type = lib.types.port;
|
|
description = lib.mdDoc "HKP port to listen on.";
|
|
};
|
|
|
|
settings = lib.mkOption {
|
|
type = settingsFormat.type;
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
hockeypuck = {
|
|
loglevel = "INFO";
|
|
logfile = "/var/log/hockeypuck/hockeypuck.log";
|
|
indexTemplate = "''${pkgs.hockeypuck-web}/share/templates/index.html.tmpl";
|
|
vindexTemplate = "''${pkgs.hockeypuck-web}/share/templates/index.html.tmpl";
|
|
statsTemplate = "''${pkgs.hockeypuck-web}/share/templates/stats.html.tmpl";
|
|
webroot = "''${pkgs.hockeypuck-web}/share/webroot";
|
|
|
|
hkp.bind = ":''${toString cfg.port}";
|
|
|
|
openpgp.db = {
|
|
driver = "postgres-jsonb";
|
|
dsn = "database=hockeypuck host=/var/run/postgresql sslmode=disable";
|
|
};
|
|
};
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Configuration file for hockeypuck, here you can override
|
|
certain settings (`loglevel` and
|
|
`openpgp.db.dsn`) by just setting those values.
|
|
|
|
For other settings you need to use lib.mkForce to override them.
|
|
|
|
This service doesn't provision or enable postgres on your
|
|
system, it rather assumes that you enable postgres and create
|
|
the database yourself.
|
|
|
|
Example:
|
|
```
|
|
services.postgresql = {
|
|
enable = true;
|
|
ensureDatabases = [ "hockeypuck" ];
|
|
ensureUsers = [{
|
|
name = "hockeypuck";
|
|
ensureDBOwnership = true;
|
|
}];
|
|
};
|
|
```
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
services.hockeypuck.settings.hockeypuck = {
|
|
loglevel = lib.mkDefault "INFO";
|
|
logfile = "/var/log/hockeypuck/hockeypuck.log";
|
|
indexTemplate = "${pkgs.hockeypuck-web}/share/templates/index.html.tmpl";
|
|
vindexTemplate = "${pkgs.hockeypuck-web}/share/templates/index.html.tmpl";
|
|
statsTemplate = "${pkgs.hockeypuck-web}/share/templates/stats.html.tmpl";
|
|
webroot = "${pkgs.hockeypuck-web}/share/webroot";
|
|
|
|
hkp.bind = ":${toString cfg.port}";
|
|
|
|
openpgp.db = {
|
|
driver = "postgres-jsonb";
|
|
dsn = lib.mkDefault "database=hockeypuck host=/var/run/postgresql sslmode=disable";
|
|
};
|
|
};
|
|
|
|
users.users.hockeypuck = {
|
|
isSystemUser = true;
|
|
group = "hockeypuck";
|
|
description = "Hockeypuck user";
|
|
};
|
|
users.groups.hockeypuck = {};
|
|
|
|
systemd.services.hockeypuck = {
|
|
description = "Hockeypuck OpenPGP Key Server";
|
|
after = [ "network.target" "postgresql.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
serviceConfig = {
|
|
WorkingDirectory = "/var/lib/hockeypuck";
|
|
User = "hockeypuck";
|
|
ExecStart = "${pkgs.hockeypuck}/bin/hockeypuck -config ${settingsFormat.generate "config.toml" cfg.settings}";
|
|
Restart = "always";
|
|
RestartSec = "5s";
|
|
LogsDirectory = "hockeypuck";
|
|
LogsDirectoryMode = "0755";
|
|
StateDirectory = "hockeypuck";
|
|
};
|
|
};
|
|
};
|
|
}
|