aa385c97e5
1. Remove `rec` keyword in favor of passing a function to `stdenv.mkDerivation`; 2. Reorder attributes; 3. Put build only dependencies --- Hare's third party libraries --- into `nativeBuildInputs`; 4. Remove `preConfigure` hook in favor of setting the `HARECACHE` make variable; 5. Use `stdenv.hostPlatform.uname.processor` for setting the architecture needed for cross-compilation; 6. Substitute in place the `HAREFLAGS` make variable instead of the `-a` flag directly, which is now set on the make variable (this should be submitted upstream, since the make variable, as of now, does absolutely nothing); 8. Pass the `-q` flag to `HAREFLAGS` to avoid polluting the logs when hare is either being called with `test` or `build`; 9. Remove deprecated `agpl3` license in favor of `agpl3Plus`; 10. Add `bonsaictl` as `meta.mainProgram`; and 11. Enable parallel building.
54 lines
1.1 KiB
Nix
54 lines
1.1 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromSourcehut
|
|
, gitUpdater
|
|
, hare
|
|
, hareThirdParty
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "bonsai";
|
|
version = "1.0.2";
|
|
|
|
src = fetchFromSourcehut {
|
|
owner = "~stacyharper";
|
|
repo = "bonsai";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-Yosf07KUOQv4O5111tLGgI270g0KVGwzdTPtPOsTcP8=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
hare
|
|
hareThirdParty.hare-ev
|
|
hareThirdParty.hare-json
|
|
];
|
|
|
|
makeFlags = [
|
|
"PREFIX=${builtins.placeholder "out"}"
|
|
"HARECACHE=.harecache"
|
|
"HAREFLAGS=-qa${stdenv.hostPlatform.uname.processor}"
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
doCheck = true;
|
|
|
|
postPatch = ''
|
|
substituteInPlace Makefile \
|
|
--replace 'hare build' 'hare build $(HAREFLAGS)' \
|
|
--replace 'hare test' 'hare test $(HAREFLAGS)'
|
|
'';
|
|
|
|
passthru.updateScript = gitUpdater {
|
|
rev-prefix = "v";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Finite State Machine structured as a tree";
|
|
homepage = "https://git.sr.ht/~stacyharper/bonsai";
|
|
license = licenses.agpl3Plus;
|
|
maintainers = with maintainers; [ colinsane ];
|
|
platforms = platforms.linux;
|
|
mainProgram = "bonsaictl";
|
|
};
|
|
})
|