4c8ec5e12e
The current version of v8 breaks builds of nodejs, mongodb and rethinkdb. So let's bring back the old package with annoying _3_14 version suffix so hopefully the corresponding maintainers will get rid of that dependency :-) Signed-off-by: aszlig <aszlig@redmoonstudios.org>
56 lines
1.7 KiB
Nix
56 lines
1.7 KiB
Nix
{ stdenv, fetchurl, openssl, python, zlib, v8_3_14, utillinux, http-parser, c-ares, pkgconfig, runCommand }:
|
|
|
|
let
|
|
dtrace = runCommand "dtrace-native" {} ''
|
|
mkdir -p $out/bin
|
|
ln -sv /usr/sbin/dtrace $out/bin
|
|
'';
|
|
|
|
version = "0.10.26";
|
|
|
|
# !!! Should we also do shared libuv?
|
|
deps = {
|
|
inherit v8_3_14 openssl zlib http-parser;
|
|
cares = c-ares;
|
|
};
|
|
|
|
sharedConfigureFlags = name: [
|
|
"--shared-${name}"
|
|
"--shared-${name}-includes=${builtins.getAttr name deps}/include"
|
|
"--shared-${name}-libpath=${builtins.getAttr name deps}/lib"
|
|
];
|
|
|
|
inherit (stdenv.lib) concatMap optional optionals maintainers licenses platforms;
|
|
in stdenv.mkDerivation {
|
|
name = "nodejs-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://nodejs.org/dist/v${version}/node-v${version}.tar.gz";
|
|
sha256 = "1ahx9cf2irp8injh826sk417wd528awi4l1mh7vxg7k8yak4wppg";
|
|
};
|
|
|
|
configureFlags = concatMap sharedConfigureFlags (builtins.attrNames deps);
|
|
|
|
prePatch = ''
|
|
sed -e 's|^#!/usr/bin/env python$|#!${python}/bin/python|g' -i configure
|
|
'';
|
|
|
|
patches = if stdenv.isDarwin then [ ./no-xcode.patch ] else null;
|
|
|
|
postPatch = if stdenv.isDarwin then ''
|
|
(cd tools/gyp; patch -Np1 -i ${../../python-modules/gyp/no-darwin-cflags.patch})
|
|
'' else null;
|
|
|
|
buildInputs = [ python ]
|
|
++ (optional stdenv.isLinux utillinux)
|
|
++ optionals stdenv.isDarwin [ pkgconfig openssl dtrace ];
|
|
setupHook = ./setup-hook.sh;
|
|
|
|
meta = {
|
|
description = "Event-driven I/O framework for the V8 JavaScript engine";
|
|
homepage = http://nodejs.org;
|
|
license = licenses.mit;
|
|
maintainers = [ maintainers.goibhniu maintainers.shlevy ];
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
};
|
|
}
|