ef91c7bcd8
`newsboat` contains quite a bit of C++ code built by custom Makefile.
`rust` code and tests already get build in parallel. The change enables
build parallelism for custom Makefile as well.
The effect on my machine is 78% build time reduction (4.5x speedup):
Before the change:
$ time nix build -f. newsboat --rebuild
real 6m20,904s
user 0m0,345s
sys 0m0,167s
After the change:
$ time nix build -f. newsboat
...
real 1m23,592s
user 0m0,277s
sys 0m0,097s
65 lines
1.9 KiB
Nix
65 lines
1.9 KiB
Nix
{ lib, stdenv, rustPlatform, fetchFromGitHub, stfl, sqlite, curl, gettext, pkg-config, libxml2, json_c, ncurses
|
|
, asciidoctor, libiconv, Security, Foundation, makeWrapper }:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "newsboat";
|
|
version = "2.30.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "newsboat";
|
|
repo = "newsboat";
|
|
rev = "r${version}";
|
|
hash = "sha256-hiZN3wWknshP8MG4ThhbMLyhQkuFozzoETs3mYaMVro=";
|
|
};
|
|
|
|
cargoHash = "sha256-Ap8i8hLqrUi6aSn4wKAdG3Z/5or+bF+epDaWUdWYt78";
|
|
|
|
# TODO: Check if that's still needed
|
|
postPatch = lib.optionalString stdenv.isDarwin ''
|
|
# Allow other ncurses versions on Darwin
|
|
substituteInPlace config.sh \
|
|
--replace "ncurses5.4" "ncurses"
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
asciidoctor
|
|
gettext
|
|
] ++ lib.optionals stdenv.isDarwin [ makeWrapper ncurses ];
|
|
|
|
buildInputs = [ stfl sqlite curl libxml2 json_c ncurses ]
|
|
++ lib.optionals stdenv.isDarwin [ Security Foundation libiconv gettext ];
|
|
|
|
postBuild = ''
|
|
make -j $NIX_BUILD_CORES prefix="$out"
|
|
'';
|
|
|
|
# https://github.com/NixOS/nixpkgs/pull/98471#issuecomment-703100014 . We set
|
|
# these for all platforms, since upstream's gettext crate behavior might
|
|
# change in the future.
|
|
GETTEXT_LIB_DIR = "${lib.getLib gettext}/lib";
|
|
GETTEXT_INCLUDE_DIR = "${lib.getDev gettext}/include";
|
|
GETTEXT_BIN_DIR = "${lib.getBin gettext}/bin";
|
|
|
|
doCheck = true;
|
|
|
|
preCheck = ''
|
|
make -j $NIX_BUILD_CORES test
|
|
'';
|
|
|
|
postInstall = ''
|
|
make -j $NIX_BUILD_CORES prefix="$out" install
|
|
'' + lib.optionalString stdenv.isDarwin ''
|
|
for prog in $out/bin/*; do
|
|
wrapProgram "$prog" --prefix DYLD_LIBRARY_PATH : "${stfl}/lib"
|
|
done
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://newsboat.org/";
|
|
description = "A fork of Newsbeuter, an RSS/Atom feed reader for the text console";
|
|
maintainers = with maintainers; [ dotlambda nicknovitski ];
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|