2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
103 lines
2.6 KiB
Nix
103 lines
2.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
cfg = config.services.metabase;
|
|
|
|
inherit (lib) mkEnableOption mkIf mkOption;
|
|
inherit (lib) optional optionalAttrs types;
|
|
|
|
dataDir = "/var/lib/metabase";
|
|
|
|
in {
|
|
|
|
options = {
|
|
|
|
services.metabase = {
|
|
enable = mkEnableOption "Metabase service";
|
|
|
|
listen = {
|
|
ip = mkOption {
|
|
type = types.str;
|
|
default = "0.0.0.0";
|
|
description = lib.mdDoc ''
|
|
IP address that Metabase should listen on.
|
|
'';
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 3000;
|
|
description = lib.mdDoc ''
|
|
Listen port for Metabase.
|
|
'';
|
|
};
|
|
};
|
|
|
|
ssl = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable SSL (https) support.
|
|
'';
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 8443;
|
|
description = lib.mdDoc ''
|
|
Listen port over SSL (https) for Metabase.
|
|
'';
|
|
};
|
|
|
|
keystore = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = "${dataDir}/metabase.jks";
|
|
example = "/etc/secrets/keystore.jks";
|
|
description = lib.mdDoc ''
|
|
[Java KeyStore](https://www.digitalocean.com/community/tutorials/java-keytool-essentials-working-with-java-keystores) file containing the certificates.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
openFirewall = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Open ports in the firewall for Metabase.
|
|
'';
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
systemd.services.metabase = {
|
|
description = "Metabase server";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network-online.target" ];
|
|
environment = {
|
|
MB_PLUGINS_DIR = "${dataDir}/plugins";
|
|
MB_DB_FILE = "${dataDir}/metabase.db";
|
|
MB_JETTY_HOST = cfg.listen.ip;
|
|
MB_JETTY_PORT = toString cfg.listen.port;
|
|
} // optionalAttrs (cfg.ssl.enable) {
|
|
MB_JETTY_SSL = true;
|
|
MB_JETTY_SSL_PORT = toString cfg.ssl.port;
|
|
MB_JETTY_SSL_KEYSTORE = cfg.ssl.keystore;
|
|
};
|
|
serviceConfig = {
|
|
DynamicUser = true;
|
|
StateDirectory = baseNameOf dataDir;
|
|
ExecStart = "${pkgs.metabase}/bin/metabase";
|
|
};
|
|
};
|
|
|
|
networking.firewall = mkIf cfg.openFirewall {
|
|
allowedTCPPorts = [ cfg.listen.port ] ++ optional cfg.ssl.enable cfg.ssl.port;
|
|
};
|
|
|
|
};
|
|
}
|