2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
114 lines
2.8 KiB
Nix
114 lines
2.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
inherit (lib) escapeShellArgs mkEnableOption mkIf mkOption types;
|
|
|
|
cfg = config.services.loki;
|
|
|
|
prettyJSON = conf:
|
|
pkgs.runCommand "loki-config.json" { } ''
|
|
echo '${builtins.toJSON conf}' | ${pkgs.jq}/bin/jq 'del(._module)' > $out
|
|
'';
|
|
|
|
in {
|
|
options.services.loki = {
|
|
enable = mkEnableOption "loki";
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = "loki";
|
|
description = lib.mdDoc ''
|
|
User under which the Loki service runs.
|
|
'';
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "loki";
|
|
description = lib.mdDoc ''
|
|
Group under which the Loki service runs.
|
|
'';
|
|
};
|
|
|
|
dataDir = mkOption {
|
|
type = types.path;
|
|
default = "/var/lib/loki";
|
|
description = lib.mdDoc ''
|
|
Specify the directory for Loki.
|
|
'';
|
|
};
|
|
|
|
configuration = mkOption {
|
|
type = (pkgs.formats.json {}).type;
|
|
default = {};
|
|
description = lib.mdDoc ''
|
|
Specify the configuration for Loki in Nix.
|
|
'';
|
|
};
|
|
|
|
configFile = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Specify a configuration file that Loki should use.
|
|
'';
|
|
};
|
|
|
|
extraFlags = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
example = [ "--server.http-listen-port=3101" ];
|
|
description = lib.mdDoc ''
|
|
Specify a list of additional command line flags,
|
|
which get escaped and are then passed to Loki.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [{
|
|
assertion = (
|
|
(cfg.configuration == {} -> cfg.configFile != null) &&
|
|
(cfg.configFile != null -> cfg.configuration == {})
|
|
);
|
|
message = ''
|
|
Please specify either
|
|
'services.loki.configuration' or
|
|
'services.loki.configFile'.
|
|
'';
|
|
}];
|
|
|
|
environment.systemPackages = [ pkgs.grafana-loki ]; # logcli
|
|
|
|
users.groups.${cfg.group} = { };
|
|
users.users.${cfg.user} = {
|
|
description = "Loki Service User";
|
|
group = cfg.group;
|
|
home = cfg.dataDir;
|
|
createHome = true;
|
|
isSystemUser = true;
|
|
};
|
|
|
|
systemd.services.loki = {
|
|
description = "Loki Service Daemon";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = let
|
|
conf = if cfg.configFile == null
|
|
then prettyJSON cfg.configuration
|
|
else cfg.configFile;
|
|
in
|
|
{
|
|
ExecStart = "${pkgs.grafana-loki}/bin/loki --config.file=${conf} ${escapeShellArgs cfg.extraFlags}";
|
|
User = cfg.user;
|
|
Restart = "always";
|
|
PrivateTmp = true;
|
|
ProtectHome = true;
|
|
ProtectSystem = "full";
|
|
DevicePolicy = "closed";
|
|
NoNewPrivileges = true;
|
|
WorkingDirectory = cfg.dataDir;
|
|
};
|
|
};
|
|
};
|
|
}
|