2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
92 lines
2.4 KiB
Nix
92 lines
2.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.miredo;
|
|
pidFile = "/run/miredo.pid";
|
|
miredoConf = pkgs.writeText "miredo.conf" ''
|
|
InterfaceName ${cfg.interfaceName}
|
|
ServerAddress ${cfg.serverAddress}
|
|
${optionalString (cfg.bindAddress != null) "BindAddress ${cfg.bindAddress}"}
|
|
${optionalString (cfg.bindPort != null) "BindPort ${cfg.bindPort}"}
|
|
'';
|
|
in
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.miredo = {
|
|
|
|
enable = mkEnableOption "the Miredo IPv6 tunneling service";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.miredo;
|
|
defaultText = literalExpression "pkgs.miredo";
|
|
description = lib.mdDoc ''
|
|
The package to use for the miredo daemon's binary.
|
|
'';
|
|
};
|
|
|
|
serverAddress = mkOption {
|
|
default = "teredo.remlab.net";
|
|
type = types.str;
|
|
description = lib.mdDoc ''
|
|
The hostname or primary IPv4 address of the Teredo server.
|
|
This setting is required if Miredo runs as a Teredo client.
|
|
"teredo.remlab.net" is an experimental service for testing only.
|
|
Please use another server for production and/or large scale deployments.
|
|
'';
|
|
};
|
|
|
|
interfaceName = mkOption {
|
|
default = "teredo";
|
|
type = types.str;
|
|
description = lib.mdDoc ''
|
|
Name of the network tunneling interface.
|
|
'';
|
|
};
|
|
|
|
bindAddress = mkOption {
|
|
default = null;
|
|
type = types.nullOr types.str;
|
|
description = lib.mdDoc ''
|
|
Depending on the local firewall/NAT rules, you might need to force
|
|
Miredo to use a fixed UDP port and or IPv4 address.
|
|
'';
|
|
};
|
|
|
|
bindPort = mkOption {
|
|
default = null;
|
|
type = types.nullOr types.str;
|
|
description = lib.mdDoc ''
|
|
Depending on the local firewall/NAT rules, you might need to force
|
|
Miredo to use a fixed UDP port and or IPv4 address.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
systemd.services.miredo = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
description = "Teredo IPv6 Tunneling Daemon";
|
|
serviceConfig = {
|
|
Restart = "always";
|
|
RestartSec = "5s";
|
|
ExecStart = "${cfg.package}/bin/miredo -c ${miredoConf} -p ${pidFile} -f";
|
|
ExecReload = "${pkgs.coreutils}/bin/kill -HUP $MAINPID";
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
}
|