3cb745d5a6
This makes those files a bit easier to read. Also, for what it's worth, it brings us one baby step closer to handling spaces in store paths. Also, I optimized handling of many transitive deps with read. Probably, not very beneficial, but nice to enforce the pkg-per-line structure. Doing so let me find much dubious code and fix it. Two misc notes: - `propagated-user-env-packages` also needed to be adjusted as sometimes it is copied to/from the propagated input files. - `local fd` should ensure that file descriptors aren't clobbered during recursion.
44 lines
1.3 KiB
Nix
44 lines
1.3 KiB
Nix
{ stdenv, fetchurl, unzip, setJavaClassPath, freetype }:
|
|
let
|
|
jdk = stdenv.mkDerivation {
|
|
name = "openjdk-7u60b30";
|
|
|
|
# From https://github.com/alexkasko/openjdk-unofficial-builds
|
|
src = fetchurl {
|
|
url = https://bitbucket.org/alexkasko/openjdk-unofficial-builds/downloads/openjdk-1.7.0-u60-unofficial-macosx-x86_64-bundle.zip;
|
|
sha256 = "af510a4d566712d82c17054bb39f91d98c69a85586e244c6123669a0bd4b7401";
|
|
};
|
|
|
|
buildInputs = [ unzip freetype ];
|
|
|
|
installPhase = ''
|
|
mv */Contents/Home $out
|
|
|
|
# jni.h expects jni_md.h to be in the header search path.
|
|
ln -s $out/include/darwin/*_md.h $out/include/
|
|
'';
|
|
|
|
preFixup = ''
|
|
# Propagate the setJavaClassPath setup hook from the JRE so that
|
|
# any package that depends on the JRE has $CLASSPATH set up
|
|
# properly.
|
|
mkdir -p $out/nix-support
|
|
printLines ${setJavaClassPath} > $out/nix-support/propagated-native-build-inputs
|
|
|
|
install_name_tool -change /usr/X11/lib/libfreetype.6.dylib ${freetype}/lib/libfreetype.6.dylib $out/jre/lib/libfontmanager.dylib
|
|
|
|
# Set JAVA_HOME automatically.
|
|
cat <<EOF >> $out/nix-support/setup-hook
|
|
if [ -z "\$JAVA_HOME" ]; then export JAVA_HOME=$out; fi
|
|
EOF
|
|
'';
|
|
|
|
passthru = {
|
|
jre = jdk;
|
|
home = jdk;
|
|
};
|
|
|
|
meta.platforms = stdenv.lib.platforms.darwin;
|
|
|
|
};
|
|
in jdk
|