7723d9935f
So that helper scripts can be easily sourced in interactive shell configuration. `autojump` package was already present and had the same requirements for findind a `share` folders, so I took an inspiration there. I beleive this is a better alternative to: - https://github.com/NixOS/nixpkgs/pull/25080 - https://github.com/NixOS/nixpkgs/pull/27058 Replacing `$out/share/shell` with `$bin/share/fzf` was necessary to prevent dependency loop in produced derivations.
59 lines
1.7 KiB
Nix
59 lines
1.7 KiB
Nix
{ stdenv, lib, ncurses, buildGoPackage, fetchFromGitHub, writeText }:
|
|
|
|
buildGoPackage rec {
|
|
name = "fzf-${version}";
|
|
version = "0.16.10";
|
|
rev = "${version}";
|
|
|
|
goPackagePath = "github.com/junegunn/fzf";
|
|
|
|
src = fetchFromGitHub {
|
|
inherit rev;
|
|
owner = "junegunn";
|
|
repo = "fzf";
|
|
sha256 = "0c9c9x2pim5g2jwy6jkdws2s7b1mw2qlnba1q46a1izswm7ljfq7";
|
|
};
|
|
|
|
outputs = [ "bin" "out" "man" ];
|
|
|
|
fishHook = writeText "load-fzf-keybindings.fish" "fzf_key_bindings";
|
|
|
|
buildInputs = [ ncurses ];
|
|
|
|
goDeps = ./deps.nix;
|
|
|
|
patchPhase = ''
|
|
sed -i -e "s|expand('<sfile>:h:h').'/bin/fzf'|'$bin/bin/fzf'|" plugin/fzf.vim
|
|
sed -i -e "s|expand('<sfile>:h:h').'/bin/fzf-tmux'|'$bin/bin/fzf-tmux'|" plugin/fzf.vim
|
|
'';
|
|
|
|
preInstall = ''
|
|
mkdir -p $bin/share/fish/vendor_functions.d $bin/share/fish/vendor_conf.d
|
|
cp $src/shell/key-bindings.fish $bin/share/fish/vendor_functions.d/fzf_key_bindings.fish
|
|
cp ${fishHook} $bin/share/fish/vendor_conf.d/load-fzf-key-bindings.fish
|
|
'';
|
|
|
|
postInstall = ''
|
|
cp $src/bin/fzf-tmux $bin/bin
|
|
mkdir -p $man/share/man
|
|
cp -r $src/man/man1 $man/share/man
|
|
mkdir -p $out/share/vim-plugins
|
|
ln -s $out/share/go/src/github.com/junegunn/fzf $out/share/vim-plugins/${name}
|
|
|
|
cp -R $src/shell $bin/share/fzf
|
|
cat <<SCRIPT > $bin/bin/fzf-share
|
|
#!/bin/sh
|
|
# Run this script to find the fzf shared folder where all the shell
|
|
# integration scripts are living.
|
|
echo $bin/share/fzf
|
|
SCRIPT
|
|
chmod +x $bin/bin/fzf-share
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://github.com/junegunn/fzf;
|
|
description = "A command-line fuzzy finder written in Go";
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|