ba12a867f7
I have no idea why gobjectIntrospection even was in here. The only library in there, libgirepository-1.0.so, is not used by awesome. It is only used by lgi.so and that means it should be found via its RPATH. The Pango path is not needed in $LD_LIBRARY_PATH ever since gobjectIntrospection started patching .typelib files with absolute paths. Relevant commits are36bef2b267from 2014 ("gobject-introspection: refer to shlibs with absolute paths in typelibs") andc420de6b05from 2016 ("gobject-introspection: Fix patching shared objects"). The above patches did not work for cairo, because cairo's typelib is a bit "special". However, this was fixed bye44038bccasome days ago ("gobjectIntrospection: use absolute path for cairo GIR"). Thus, setting $GI_TYPELIB_PATH is enough so that all needed libraries are found. Fixes: https://github.com/NixOS/nixpkgs/issues/14164 Signed-off-by: Uli Schlachter <psychon@znc.in>
71 lines
2.5 KiB
Nix
71 lines
2.5 KiB
Nix
{ stdenv, fetchFromGitHub, luaPackages, cairo, librsvg, cmake, imagemagick, pkgconfig, gdk_pixbuf
|
|
, xorg, libstartup_notification, libxdg_basedir, libpthreadstubs
|
|
, xcb-util-cursor, makeWrapper, pango, gobjectIntrospection, unclutter
|
|
, compton, procps, iproute, coreutils, curl, alsaUtils, findutils, xterm
|
|
, which, dbus, nettools, git, asciidoc, doxygen
|
|
, xmlto, docbook_xml_dtd_45, docbook_xsl, findXMLCatalogs
|
|
, libxkbcommon, xcbutilxrm, hicolor_icon_theme
|
|
}:
|
|
|
|
with luaPackages; stdenv.mkDerivation rec {
|
|
name = "awesome-${version}";
|
|
version = "4.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "awesomewm";
|
|
repo = "awesome";
|
|
rev = "v${version}";
|
|
sha256 = "1pcgagcvm6rdky8p8dd810j3ywaz0ncyk5xgaykslaixzrq60kff";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
asciidoc
|
|
cmake
|
|
doxygen
|
|
imagemagick
|
|
makeWrapper
|
|
pkgconfig
|
|
xmlto docbook_xml_dtd_45
|
|
docbook_xsl findXMLCatalogs
|
|
];
|
|
|
|
propagatedUserEnvPkgs = [ hicolor_icon_theme ];
|
|
buildInputs = [ cairo librsvg dbus gdk_pixbuf gobjectIntrospection
|
|
git lgi libpthreadstubs libstartup_notification
|
|
libxdg_basedir lua nettools pango xcb-util-cursor
|
|
xorg.libXau xorg.libXdmcp xorg.libxcb xorg.libxshmfence
|
|
xorg.xcbutil xorg.xcbutilimage xorg.xcbutilkeysyms
|
|
xorg.xcbutilrenderutil xorg.xcbutilwm libxkbcommon
|
|
xcbutilxrm ];
|
|
|
|
#cmakeFlags = "-DGENERATE_MANPAGES=ON";
|
|
cmakeFlags = "-DOVERRIDE_VERSION=${version}";
|
|
|
|
GI_TYPELIB_PATH = "${pango.out}/lib/girepository-1.0";
|
|
LUA_CPATH = "${lgi}/lib/lua/${lua.luaversion}/?.so";
|
|
LUA_PATH = "${lgi}/share/lua/${lua.luaversion}/?.lua;${lgi}/share/lua/${lua.luaversion}/lgi/?.lua";
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/awesome \
|
|
--set GDK_PIXBUF_MODULE_FILE "$GDK_PIXBUF_MODULE_FILE" \
|
|
--add-flags '--search ${lgi}/lib/lua/${lua.luaversion}' \
|
|
--add-flags '--search ${lgi}/share/lua/${lua.luaversion}' \
|
|
--prefix GI_TYPELIB_PATH : "$GI_TYPELIB_PATH" \
|
|
--prefix PATH : "${stdenv.lib.makeBinPath [ compton unclutter procps iproute coreutils curl alsaUtils findutils xterm ]}"
|
|
|
|
wrapProgram $out/bin/awesome-client \
|
|
--prefix PATH : "${which}/bin"
|
|
'';
|
|
|
|
passthru = {
|
|
inherit lua;
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Highly configurable, dynamic window manager for X";
|
|
homepage = https://awesomewm.org/;
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ lovek323 rasendubi ndowens ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|