f5fa5fa4d6
* pkgs: refactor needless quoting of homepage meta attribute A lot of packages are needlessly quoting the homepage meta attribute (about 1400, 22%), this commit refactors all of those instances. * pkgs: Fixing some links that were wrongfully unquoted in the previous commit * Fixed some instances
45 lines
1.7 KiB
Nix
45 lines
1.7 KiB
Nix
{ stdenv, fetchurl, autoreconfHook, unzip, m4, bison, flex, openssl, zlib }:
|
|
|
|
let
|
|
majorVersion = "2.8";
|
|
|
|
in stdenv.mkDerivation rec {
|
|
name = "gsoap-${version}";
|
|
version = "${majorVersion}.49";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/project/gsoap2/gsoap-${majorVersion}/gsoap_${version}.zip";
|
|
sha256 = "0414q7zabkq3iiccl2yql3vbihbr7ach9d517b37zv3mp7nhj2aj";
|
|
};
|
|
|
|
buildInputs = [ openssl zlib ];
|
|
nativeBuildInputs = [ autoreconfHook bison flex m4 unzip ];
|
|
# Parallel building doesn't work as of 2.8.49
|
|
enableParallelBuilding = false;
|
|
|
|
# Future versions of automake require subdir-objects if the source is structured this way
|
|
# As of 2.8.49 (maybe earlier) this is needed to silence warnings
|
|
prePatch = ''
|
|
substituteInPlace configure.ac \
|
|
--replace 'AM_INIT_AUTOMAKE([foreign])' 'AM_INIT_AUTOMAKE([foreign subdir-objects])'
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "C/C++ toolkit for SOAP web services and XML-based applications";
|
|
homepage = http://www.cs.fsu.edu/~engelen/soap.html;
|
|
# gsoap is dual/triple licensed (see homepage for details):
|
|
# 1. gSOAP Public License 1.3 (based on Mozilla Public License 1.1).
|
|
# Components NOT covered by the gSOAP Public License are:
|
|
# - wsdl2h tool and its source code output,
|
|
# - soapcpp2 tool and its source code output,
|
|
# - UDDI code,
|
|
# - the webserver example code in gsoap/samples/webserver,
|
|
# - and several example applications in the gsoap/samples directory.
|
|
# 2. GPLv2 covers all of the software
|
|
# 3. Proprietary commercial software development license (removes GPL
|
|
# restrictions)
|
|
license = licenses.gpl2;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ bjornfor ];
|
|
};
|
|
}
|