2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
60 lines
1.5 KiB
Nix
60 lines
1.5 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.uptimed;
|
|
stateDir = "/var/lib/uptimed";
|
|
in
|
|
{
|
|
options = {
|
|
services.uptimed = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Enable `uptimed`, allowing you to track
|
|
your highest uptimes.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
environment.systemPackages = [ pkgs.uptimed ];
|
|
|
|
users.users.uptimed = {
|
|
description = "Uptimed daemon user";
|
|
home = stateDir;
|
|
uid = config.ids.uids.uptimed;
|
|
group = "uptimed";
|
|
};
|
|
users.groups.uptimed = {};
|
|
|
|
systemd.services.uptimed = {
|
|
unitConfig.Documentation = "man:uptimed(8) man:uprecords(1)";
|
|
description = "uptimed service";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
Restart = "on-failure";
|
|
User = "uptimed";
|
|
Nice = 19;
|
|
IOSchedulingClass = "idle";
|
|
PrivateTmp = "yes";
|
|
PrivateNetwork = "yes";
|
|
NoNewPrivileges = "yes";
|
|
StateDirectory = [ "uptimed" ];
|
|
InaccessibleDirectories = "/home";
|
|
ExecStart = "${pkgs.uptimed}/sbin/uptimed -f -p ${stateDir}/pid";
|
|
};
|
|
|
|
preStart = ''
|
|
if ! test -f ${stateDir}/bootid ; then
|
|
${pkgs.uptimed}/sbin/uptimed -b
|
|
fi
|
|
'';
|
|
};
|
|
};
|
|
}
|