9833d56c24
Done with the help of https://github.com/Mindavi/nixpkgs-mark-broken Tool is still WIP but this is one of the first results. I manually audited the results and removed some results that were not valid. Note that some of these packages maybe should have more constrained platforms set instead of broken set, but I think not being perfectly correct is better than just keep trying to build all these things and never succeeding. Some observations: - Some darwin builds require XCode tools - aarch64-linux builds sometimes suffer from using gcc9 - gcc9 is getting older and misses some new libraries/features - Sometimes tools try to do system detection or expect some explicit settings for platforms that are not x86_64-linux
76 lines
1.8 KiB
Nix
76 lines
1.8 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromGitHub
|
|
, nix-update-script
|
|
, cmake
|
|
, pkg-config
|
|
, makeWrapper
|
|
, zlib
|
|
, libX11
|
|
, libXrandr
|
|
, libXinerama
|
|
, libXcursor
|
|
, libXi
|
|
, libXext
|
|
, libGLU
|
|
, alsa-lib
|
|
, fontconfig
|
|
, AVFoundation
|
|
, Carbon
|
|
, Cocoa
|
|
, CoreAudio
|
|
, Kernel
|
|
, OpenGL
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "foxotron";
|
|
version = "2022-11-02";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Gargaj";
|
|
repo = "Foxotron";
|
|
rev = version;
|
|
fetchSubmodules = true;
|
|
sha256 = "sha256-WjsVvFhwVCzclHxA+Gu2YtR2yK0Opqhncwlg9FEhOLk=";
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake pkg-config makeWrapper ];
|
|
|
|
buildInputs = [ zlib ]
|
|
++ lib.optionals stdenv.hostPlatform.isLinux [ libX11 libXrandr libXinerama libXcursor libXi libXext alsa-lib fontconfig libGLU ]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [ AVFoundation Carbon Cocoa CoreAudio Kernel OpenGL ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/{bin,lib/foxotron}
|
|
cp -R ${lib.optionalString stdenv.hostPlatform.isDarwin "Foxotron.app/Contents/MacOS/"}Foxotron \
|
|
../{config.json,Shaders,Skyboxes} $out/lib/foxotron/
|
|
wrapProgram $out/lib/foxotron/Foxotron \
|
|
--chdir "$out/lib/foxotron"
|
|
ln -s $out/{lib/foxotron,bin}/Foxotron
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru = {
|
|
updateScript = nix-update-script {
|
|
attrPath = pname;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "General purpose model viewer";
|
|
longDescription = ''
|
|
ASSIMP based general purpose model viewer ("turntable") created for the
|
|
Revision 2021 3D Graphics Competition.
|
|
'';
|
|
homepage = "https://github.com/Gargaj/Foxotron";
|
|
license = licenses.unlicense;
|
|
maintainers = with maintainers; [ OPNA2608 ];
|
|
platforms = platforms.all;
|
|
# never built on aarch64-darwin since first introduction in nixpkgs
|
|
broken = stdenv.isDarwin && stdenv.isAarch64;
|
|
};
|
|
}
|