55e6303d6a
Some packages in the llvm suite (e.g. compiler-rt) cannot be built separate from the build of llvm, and while some others (e.g. clang) can the combined build is much better tested (we've had to work around annoying issues before). So this puts llvm, clang, clang-tools-extra, compiler-rt, lld, lldb, and polly all into one big build (llvmFull). This build includes a static llvm, as dynamic is similarly less tested and has known failures. This also updates libc++ and dragonegg. libc++ now builds against libc++abi as a separate package rather than building it during the libc++ build. The clang purity patch is gone. Instead, we simply set --sysroot to /var/empty for pure builds, as all impure paths are either looked up in the gcc prefix (which we hard-code at compile time) or in the sysroot. This also means that if NIX_ENFORCE_PURITY is 0 then clang will look in the normal Linux paths by default, which is the proper behavior IMO. polly required an updated isl. When stdenv-updates is merged, perhaps we can update the isl used by gcc and avoid having two versions. Since llvm on its own is now separate from the llvm used by clang, I've removed myself as maintainer from llvm and will leave maintenance of that to those who are interested in llvm separate from clang. Signed-off-by: Shea Levy <shea@shealevy.com>
47 lines
1.7 KiB
Nix
47 lines
1.7 KiB
Nix
{ stdenv, fetchurl, perl, groff, cmake, python, libffi, binutils_gold, version }:
|
|
|
|
with { inherit (stdenv.lib) optional; };
|
|
|
|
assert version == "3.4" || version == "3.3";
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "llvm-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://llvm.org/releases/${version}/llvm-${version}.src.tar.gz";
|
|
sha256 =
|
|
if version == "3.4" then "0a169ba045r4apb9cv6ncrwl83l7yiajnzirkcdlhj1cd4nn3995"
|
|
else /*3.3*/ "0y3mfbb5qzcpw3v5qncn69x1hdrrrfirgs82ypi2annhf0g6nxk8";
|
|
};
|
|
|
|
# The default rlimits are too low for shared libraries.
|
|
patches = optional (version == "3.3") [ ./more-memory-for-bugpoint.patch ];
|
|
|
|
# libffi was propagated before, but it wasn't even being used, so
|
|
# unless something needs it just an input is fine.
|
|
buildInputs = [ perl groff cmake python libffi ]; # ToDo: polly, libc++; enable cxx11?
|
|
|
|
# hacky fix: created binaries need to be run before installation
|
|
preBuild = let LD = if stdenv.isDarwin then "DYLD" else "LD";
|
|
in "export ${LD}_LIBRARY_PATH='$$${LD}_LIBRARY_PATH:'`pwd`/lib";
|
|
|
|
cmakeFlags = with stdenv; [
|
|
"-DCMAKE_BUILD_TYPE=Release"
|
|
"-DLLVM_ENABLE_FFI=ON"
|
|
"-DLLVM_BINUTILS_INCDIR=${binutils_gold}/include"
|
|
]
|
|
++ optional (version == "3.3") "-DLLVM_EXPERIMENTAL_TARGETS_TO_BUILD=R600" # for mesa
|
|
++ optional (!isDarwin) "-DBUILD_SHARED_LIBS=ON";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
doCheck = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Collection of modular and reusable compiler and toolchain technologies";
|
|
homepage = http://llvm.org/;
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ lovek323 raskin viric ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|