fd78240ac8
At some point, I'd like to make another attempt at71f1f4884b("openssl: stop static binaries referencing libs"), which was reverted in195c7da07d. One problem with my previous attempt is that I moved OpenSSL's libraries to a lib output, but many dependent packages were hardcoding the out output as the location of the libraries. This patch fixes every such case I could find in the tree. It won't have any effect immediately, but will mean these packages will automatically use an OpenSSL lib output if it is reintroduced in future. This patch should cause very few rebuilds, because it shouldn't make any change at all to most packages I'm touching. The few rebuilds that are introduced come from when I've changed a package builder not to use variable names like openssl.out in scripts / substitution patterns, which would be confusing since they don't hardcode the output any more. I started by making the following global replacements: ${pkgs.openssl.out}/lib -> ${lib.getLib pkgs.openssl}/lib ${openssl.out}/lib -> ${lib.getLib openssl}/lib Then I removed the ".out" suffix when part of the argument to lib.makeLibraryPath, since that function uses lib.getLib internally. Then I fixed up cases where openssl was part of the -L flag to the compiler/linker, since that unambigously is referring to libraries. Then I manually investigated and fixed the following packages: - pycurl - citrix-workspace - ppp - wraith - unbound - gambit - acl2 I'm reasonably confindent in my fixes for all of them. For acl2, since the openssl library paths are manually provided above anyway, I don't think openssl is required separately as a build input at all. Removing it doesn't make a difference to the output size, the file list, or the closure. I've tested evaluation with the OfBorg meta checks, to protect against introducing evaluation failures.
98 lines
3.2 KiB
Nix
98 lines
3.2 KiB
Nix
{ lib, stdenv, fetchurl, openssl, db, groff, libtool, libsodium
|
|
, withCyrusSasl ? true
|
|
, cyrus_sasl
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "openldap";
|
|
version = "2.4.58";
|
|
|
|
src = fetchurl {
|
|
url = "https://www.openldap.org/software/download/OpenLDAP/openldap-release/${pname}-${version}.tgz";
|
|
sha256 = "sha256-V7WSVL4V0L9qmrPVFMHAV3ewISMpFTMTSofJRGj49Hs=";
|
|
};
|
|
|
|
# TODO: separate "out" and "bin"
|
|
outputs = [ "out" "dev" "man" "devdoc" ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
nativeBuildInputs = [ groff ];
|
|
|
|
buildInputs = [ openssl cyrus_sasl db libsodium libtool ];
|
|
|
|
# Disable install stripping as it breaks cross-compiling.
|
|
# We strip binaries anyway in fixupPhase.
|
|
makeFlags= [
|
|
"STRIP="
|
|
"prefix=$(out)"
|
|
"moduledir=$(out)/lib/modules"
|
|
"CC=${stdenv.cc.targetPrefix}cc"
|
|
];
|
|
|
|
preConfigure = lib.optionalString (lib.versionAtLeast stdenv.hostPlatform.darwinMinVersion "11") ''
|
|
MACOSX_DEPLOYMENT_TARGET=10.16
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--enable-overlays"
|
|
"--disable-dependency-tracking" # speeds up one-time build
|
|
"--enable-modules"
|
|
"--sysconfdir=/etc"
|
|
"--localstatedir=/var"
|
|
"--enable-crypt"
|
|
] ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
|
"--with-yielding_select=yes"
|
|
"ac_cv_func_memcmp_working=yes"
|
|
] ++ lib.optional (!withCyrusSasl) "--without-cyrus-sasl"
|
|
++ lib.optional stdenv.isFreeBSD "--with-pic";
|
|
|
|
postBuild = ''
|
|
make $makeFlags CC=$CC -C contrib/slapd-modules/passwd/sha2
|
|
make $makeFlags CC=$CC -C contrib/slapd-modules/passwd/pbkdf2
|
|
make $makeFlags CC=$CC -C contrib/slapd-modules/passwd/argon2
|
|
'';
|
|
|
|
doCheck = false; # needs a running LDAP server
|
|
|
|
installFlags = [
|
|
"sysconfdir=$(out)/etc"
|
|
"localstatedir=$(out)/var"
|
|
"moduledir=$(out)/lib/modules"
|
|
# The argon2 module hardcodes /usr/bin/install as the path for the
|
|
# `install` binary, which is overridden here.
|
|
"INSTALL=install"
|
|
];
|
|
|
|
# 1. Libraries left in the build location confuse `patchelf --shrink-rpath`
|
|
# Delete these to let patchelf discover the right path instead.
|
|
# FIXME: that one can be removed when https://github.com/NixOS/patchelf/pull/98
|
|
# is in Nixpkgs patchelf.
|
|
# 2. Fixup broken libtool for openssl and cyrus_sasl (if it is not disabled)
|
|
preFixup = ''
|
|
rm -r $out/var
|
|
rm -r libraries/*/.libs
|
|
rm -r contrib/slapd-modules/passwd/*/.libs
|
|
for f in $out/lib/libldap.la $out/lib/libldap_r.la; do
|
|
substituteInPlace "$f" --replace '-lssl' '-L${lib.getLib openssl}/lib -lssl'
|
|
'' + lib.optionalString withCyrusSasl ''
|
|
substituteInPlace "$f" --replace '-lsasl2' '-L${cyrus_sasl.out}/lib -lsasl2'
|
|
'' + ''
|
|
done
|
|
'';
|
|
|
|
postInstall = ''
|
|
make $installFlags install -C contrib/slapd-modules/passwd/sha2
|
|
make $installFlags install -C contrib/slapd-modules/passwd/pbkdf2
|
|
make $installFlags install-lib -C contrib/slapd-modules/passwd/argon2
|
|
chmod +x "$out"/lib/*.{so,dylib}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.openldap.org/";
|
|
description = "An open source implementation of the Lightweight Directory Access Protocol";
|
|
license = licenses.openldap;
|
|
maintainers = with maintainers; [ lovek323 ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|